以下部分将引导你完成一个拆解示例。
源代码
下面是将分析的函数的代码。
HRESULT CUserView::CloseView(void)
{
if (m_fDestroyed) return S_OK;
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
if (m_psv) {
m_psb->EnableModelessSB(FALSE);
if(m_pws) m_pws->ViewReleased();
IShellView* psv;
HWND hwndCapture = GetCapture();
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
NotifyClients(m_psv, NOTIFY_CLOSING);
m_fRecursing = FALSE;
m_psv->UIActivate(SVUIA_DEACTIVATE);
psv = m_psv;
m_psv = NULL;
ReleaseAndNull(&_pctView);
if (m_pvo) {
IAdviseSink *pSink;
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
if (pSink == (IAdviseSink *)this)
m_pvo->SetAdvise(0, 0, NULL);
pSink->Release();
}
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
}
if (psv) {
psv->SaveViewState();
psv->DestroyViewWindow();
psv->Release();
}
m_hwndView = NULL;
m_fHandsOff = FALSE;
if (m_pcache) {
GlobalFree(m_pcache);
m_pcache = NULL;
}
m_psb->EnableModelessSB(TRUE);
CancelPendingActions();
}
ReleaseAndNull(&_psf);
if (fViewObjectChanged)
NotifyViewClients(DVASPECT_CONTENT, -1);
if (m_pszTitle) {
LocalFree(m_pszTitle);
m_pszTitle = NULL;
}
SetRect(&m_rcBounds, 0, 0, 0, 0);
return S_OK;
}
程序集代码
本部分包含带批注的反汇编示例。
使用 ebp 寄存器作为帧指针的函数开始如下：
HRESULT CUserView::CloseView(void)
SAMPLE!CUserView__CloseView:
71517134 55 push ebp
71517135 8bec mov ebp,esp
这会设置帧，以便函数可以将其参数作为 ebp 的正偏移量进行访问，并将局部变量作为负偏移量进行访问。
这是专用 COM 接口上的一种方法，因此调用约定 __stdcall。 这意味着参数从右至左推送（在本例中没有参数），接着推送 'this' 指针，然后调用函数。 因此，在进入函数时，堆栈如下所示：
[esp+0] = return address
[esp+4] = this
在上述两条指令之后，可以访问这些参数：
[ebp+0] = previous ebp pushed on stack
[ebp+4] = return address
[ebp+8] = this
对于使用 ebp 作为帧指针的函数，可通过 [ebp+8] 访问第一个推送参数;后续参数可在连续更高的 DWORD 地址中访问。
71517137 51 push ecx
71517138 51 push ecx
此函数只需要两个局部堆栈变量，因此一个 sub esp, 8 指令。 然后，推送的值可用作 [ebp-4] 和 [ebp-8]。
对于使用 ebp 作为帧指针的函数，可通过 ebp 寄存器的负偏移量访问堆栈局部变量。
71517139 56 push esi
现在，编译器会保存所有在函数调用期间需要保留的寄存器。 实际上，它会以零散的方式保存在与实际代码第一行交错的部分中。
7151713a 8b7508 mov esi,[ebp+0x8] ; esi = this
7151713d 57 push edi ; save another registers
这恰好是因为 CloseView 是 ViewState 的一个方法，该方法在底层对象中的偏移量为 12。 因此，这是指向 ViewState 类的指针。不过，当可能与其他基类混淆时，将更准确地指定为（ViewState*）this。
if (m_fDestroyed)
7151713e 33ff xor edi,edi ; edi = 0
对寄存器进行 XOR 操作使其自我归零是一种标准方法。
71517140 39beac000000 cmp [esi+0xac],edi ; this->m_fDestroyed == 0?
71517146 7407 jz NotDestroyed (7151714f) ; jump if equal
cmp 指令比较两个值（通过减去它们）。 jz 指令检查结果是否为零，指示两个比较值相等。
cmp 指令比较两个值：后续 j 指令会根据比较结果跳转。
return S_OK;
71517148 33c0 xor eax,eax ; eax = 0 = S_OK
7151714a e972010000 jmp ReturnNoEBX (715172c1) ; return, do not pop EBX
编译器延迟保存 EBX 寄存器，直到函数的后续执行阶段，因此，如果程序在此测试中要提前退出，则退出路径必须是不涉及还原 EBX 的路径。
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
这两行代码的执行是交错的，因此请注意。
NotDestroyed:
7151714f 8d86c0000000 lea eax,[esi+0xc0] ; eax = &m_pdtgt
lea 指令计算内存访问的效果地址，并将其存储在目标中。 实际内存地址未被解引用。
lea 指令采用变量的地址。
71517155 53 push ebx
您应该在它可能损坏之前保存 EBX 寄存器。
71517156 8b1d10195071 mov ebx,[_imp__ReleaseAndNull]
由于经常调用 ReleaseAndNull ，因此最好在 EBX 中缓存其地址。
7151715c 50 push eax ; parameter to ReleaseAndNull
7151715d 897dfc mov [ebp-0x4],edi ; fViewObjectChanged = FALSE
71517160 ffd3 call ebx ; call ReleaseAndNull
if (m_psv) {
71517162 397e74 cmp [esi+0x74],edi ; this->m_psv == 0?
71517165 0f8411010000 je No_Psv (7151727c) ; jump if zero
请记住，之前已将 EDI 寄存器清零，并且 EDI 是跨函数调用时保留的寄存器（因此，调用 ReleaseAndNull 并没有更改它）。 因此，它仍然保留零值，可以使用它快速测试是否为零。
m_psb->EnableModelessSB(FALSE);
7151716b 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151716e 57 push edi ; FALSE
7151716f 50 push eax ; "this" for callee
71517170 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
71517172 ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
上述模式是 COM 方法调用的指示符号。
COM 方法调用相当流行，因此学会识别它们是一个好主意。 具体而言，应该能够直接从其 Vtable 偏移量识别三个 IUnknown 方法：QueryInterface=0、AddRef=4 和 Release=8。
if(m_pws) m_pws->ViewReleased();
71517175 8b8614010000 mov eax,[esi+0x114] ; eax = this->m_pws
7151717b 3bc7 cmp eax,edi ; eax == 0?
7151717d 7406 jz NoWS (71517185) ; if so, then jump
7151717f 8b08 mov ecx,[eax] ; ecx = m_pws->lpVtbl
71517181 50 push eax ; "this" for callee
71517182 ff510c call [ecx+0xc] ; __stdcall ViewReleased
NoWS:
HWND hwndCapture = GetCapture();
71517185 ff15e01a5071 call [_imp__GetCapture] ; call GetCapture
通过全局的间接调用是在 Microsoft Win32 中实现函数导入的方式。 加载程序调整全局变量，使其指向目标的实际地址。 这是一种方便的方法，可以帮助您在调查崩溃的机器时了解情况。 查找对导入的函数和目标中的调用。 通常，你将会有某个导入函数的名称，可以用来确定你在源代码中的位置。
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
7151718b 3bc7 cmp eax,edi ; hwndCapture == 0?
7151718d 7412 jz No_Capture (715171a1) ; jump if zero
函数返回值放置在 EAX 寄存器中。
7151718f 8b4e44 mov ecx,[esi+0x44] ; ecx = this->m_hwnd
71517192 3bc1 cmp eax,ecx ; hwndCapture = ecx?
71517194 750b jnz No_Capture (715171a1) ; jump if not
71517196 57 push edi ; 0
71517197 57 push edi ; 0
71517198 6a1f push 0x1f ; WM_CANCELMODE
7151719a 51 push ecx ; hwndCapture
7151719b ff1518195071 call [_imp__SendMessageW] ; SendMessage
No_Capture:
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
715171a1 66818e0c0100000180 or word ptr [esi+0x10c],0x8001 ; set both flags at once
NotifyClients(m_psv, NOTIFY_CLOSING);
715171aa 8b4e20 mov ecx,[esi+0x20] ; ecx = (CNotifySource*)this.vtbl
715171ad 6a04 push 0x4 ; NOTIFY_CLOSING
715171af 8d4620 lea eax,[esi+0x20] ; eax = (CNotifySource*)this
715171b2 ff7674 push [esi+0x74] ; m_psv
715171b5 50 push eax ; "this" for callee
715171b6 ff510c call [ecx+0xc] ; __stdcall NotifyClients
请注意，当在不同于你自己的基类上调用方法时，如何更改“this”指针。
m_fRecursing = FALSE;
715171b9 80a60d0100007f and byte ptr [esi+0x10d],0x7f
m_psv->UIActivate(SVUIA_DEACTIVATE);
715171c0 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171c3 57 push edi ; SVUIA_DEACTIVATE = 0
715171c4 50 push eax ; "this" for callee
715171c5 8b08 mov ecx,[eax] ; ecx = vtbl
715171c7 ff511c call [ecx+0x1c] ; __stdcall UIActivate
psv = m_psv;
m_psv = NULL;
715171ca 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171cd 897e74 mov [esi+0x74],edi ; m_psv = NULL
715171d0 8945f8 mov [ebp-0x8],eax ; psv = eax
第一个局部变量是 psv。
ReleaseAndNull(&_pctView);
715171d3 8d466c lea eax,[esi+0x6c] ; eax = &_pctView
715171d6 50 push eax ; parameter
715171d7 ffd3 call ebx ; call ReleaseAndNull
if (m_pvo) {
715171d9 8b86a8000000 mov eax,[esi+0xa8] ; eax = m_pvo
715171df 8dbea8000000 lea edi,[esi+0xa8] ; edi = &m_pvo
715171e5 85c0 test eax,eax ; eax == 0?
715171e7 7448 jz No_Pvo (71517231) ; jump if zero
请注意，编译器预测性地准备了 m_pvo 成员的地址，因为你将在一段时间内频繁使用它。 因此，方便获取地址将导致较小的代码。
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
715171e9 8b08 mov ecx,[eax] ; ecx = m_pvo->lpVtbl
715171eb 8d5508 lea edx,[ebp+0x8] ; edx = &pSink
715171ee 52 push edx ; parameter
715171ef 6a00 push 0x0 ; NULL
715171f1 6a00 push 0x0 ; NULL
715171f3 50 push eax ; "this" for callee
715171f4 ff5120 call [ecx+0x20] ; __stdcall GetAdvise
715171f7 85c0 test eax,eax ; test bits of eax
715171f9 7c2c jl No_Advise (71517227) ; jump if less than zero
715171fb 33c9 xor ecx,ecx ; ecx = 0
715171fd 394d08 cmp [ebp+0x8],ecx ; _pSink == ecx?
71517200 7425 jz No_Advise (71517227)
请注意，编译器得出结论，传入的“this”参数不是必需的（因为它很久以前就将其藏在 ESI 寄存器中）。 因此，它将内存重用为局部变量 pSink。
如果函数使用 EBP 帧，则传入的参数将在 EBP 的正偏移量上抵达，而局部变量则放置在负偏移量上。 但是，在这种情况下，编译器可以自由重复使用该内存，以用于任何目的。
如果密切关注，你将看到编译器可以更好地优化此代码。 它可能会将 lea edi, [esi+0xa8] 指令延迟到两个 push 0x0 指令之后，然后用 push edi 替换它们。 节省了 2 个字节。
if (pSink == (IAdviseSink *)this)
接下来的几行是为了补偿在C++中，(IAdviseSink *)NULL 必须仍然是 NULL 的情况。 因此，如果“this”确实为“（ViewState*）NULL”，则转换的结果应为 NULL ，而不是 IAdviseSink 和 IBrowserService 之间的距离。
71517202 8d46ec lea eax,[esi-0x14] ; eax = -(IAdviseSink*)this
71517205 8d5614 lea edx,[esi+0x14] ; edx = (IAdviseSink*)this
71517208 f7d8 neg eax ; eax = -eax (sets carry if != 0)
7151720a 1bc0 sbb eax,eax ; eax = eax - eax - carry
7151720c 23c2 and eax,edx ; eax = NULL or edx
尽管Pentum 有条件移动指令，但基本 i386 体系结构没有，因此编译器使用特定技术来模拟条件移动指令，而无需进行任何跳转。
条件评估的一般模式如下：
neg r
sbb r, r
and r, (val1 - val2)
add r, val2
如果 r 为非零，则 neg r 设置携带标志，因为 neg 通过从零减去来求负值。 如果减去非零值，则从零减去将生成借款（设置携带）。 它还会损害 r 寄存器中的值，但这是可以接受的，因为你无论如何都即将覆盖它。
接下来，sbb r, r 指令从自身减去自身的值，结果总是为零。 但是，它还减去进位（借位）位，因此净结果是将r设置为零或-1，这具体取决于进位位是清除状态还是设置状态。
因此，如果 r 的原始值为零，则 sbb r 将 r 设置为零;如果原始值为非零，则设置为 -1。
第三个指令执行掩码。 由于 r 寄存器为零或 -1，“this”用于将 r 保持为零，或将 r 从 -1 更改为 (val1 - val1)。进行与 -1 的位与操作时，任何值都保持原样。
因此，如果 r 的原始值为零，则“and r， （val1 - val1）”的结果是将 r 设置为零;如果 r 的原始值为非零，则设置为“（val1 - val2）。”
最后，将 val2 添加到 r，导致 val2 或 （val1 - val2） + val2 = val1。
因此，此系列指令的最终结果是，如果它最初为零， 则设置为val2 ;如果它不是零，则设置为 val1 。 这是 r = r？ val1 ： val2 的程序集等效项。
在此特定实例中，可以看到 val2 = 0 和 val1 = (IAdviseSink*)此。 请注意，编译器省略了最后的 add eax, 0 指令，因为它不起作用。
7151720e 394508 cmp [ebp+0x8],eax ; pSink == (IAdviseSink*)this?
71517211 750b jnz No_SetAdvise (7151721e) ; jump if not equal
在本部分的前面，将 EDI 设置为 m_pvo 成员的地址。 现在你将使用它。 您还对 ECX 寄存器进行了置零操作。
m_pvo->SetAdvise(0, 0, NULL);
71517213 8b07 mov eax,[edi] ; eax = m_pvo
71517215 51 push ecx ; NULL
71517216 51 push ecx ; 0
71517217 51 push ecx ; 0
71517218 8b10 mov edx,[eax] ; edx = m_pvo->lpVtbl
7151721a 50 push eax ; "this" for callee
7151721b ff521c call [edx+0x1c] ; __stdcall SetAdvise
No_SetAdvise:
pSink->Release();
7151721e 8b4508 mov eax,[ebp+0x8] ; eax = pSink
71517221 50 push eax ; "this" for callee
71517222 8b08 mov ecx,[eax] ; ecx = pSink->lpVtbl
71517224 ff5108 call [ecx+0x8] ; __stdcall Release
No_Advise:
所有这些 COM 方法的调用都显得非常熟悉。
接下来两个语句的评估是交错进行的。 不要忘记 EBX 包含 ReleaseAndNull 的地址。
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
71517227 57 push edi ; &m_pvo
71517228 c745fc01000000 mov dword ptr [ebp-0x4],0x1 ; fViewObjectChanged = TRUE
7151722f ffd3 call ebx ; call ReleaseAndNull
No_Pvo:
if (psv) {
71517231 8b7df8 mov edi,[ebp-0x8] ; edi = psv
71517234 85ff test edi,edi ; edi == 0?
71517236 7412 jz No_Psv2 (7151724a) ; jump if zero
psv->SaveViewState();
71517238 8b07 mov eax,[edi] ; eax = psv->lpVtbl
7151723a 57 push edi ; "this" for callee
7151723b ff5034 call [eax+0x34] ; __stdcall SaveViewState
以下是更多的 COM 方法调用。
psv->DestroyViewWindow();
7151723e 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517240 57 push edi ; "this" for callee
71517241 ff5028 call [eax+0x28] ; __stdcall DestroyViewWindow
psv->Release();
71517244 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517246 57 push edi ; "this" for callee
71517247 ff5008 call [eax+0x8] ; __stdcall Release
No_Psv2:
m_hwndView = NULL;
7151724a 83667c00 and dword ptr [esi+0x7c],0x0 ; m_hwndView = 0
将内存位置与零进行与（AND）运算相当于将其设置为零，因为任何与零相与的结果都是零。 编译器使用此窗体，因为即使速度较慢，它比等效 的 mov 指令要短得多。 （此代码已针对大小而不是速度进行优化。
m_fHandsOff = FALSE;
7151724e 83a60c010000fe and dword ptr [esi+0x10c],0xfe
if (m_pcache) {
71517255 8b4670 mov eax,[esi+0x70] ; eax = m_pcache
71517258 85c0 test eax,eax ; eax == 0?
7151725a 740b jz No_Cache (71517267) ; jump if zero
GlobalFree(m_pcache);
7151725c 50 push eax ; m_pcache
7151725d ff15b4135071 call [_imp__GlobalFree] ; call GlobalFree
m_pcache = NULL;
71517263 83667000 and dword ptr [esi+0x70],0x0 ; m_pcache = 0
No_Cache:
m_psb->EnableModelessSB(TRUE);
71517267 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151726a 6a01 push 0x1 ; TRUE
7151726c 50 push eax ; "this" for callee
7151726d 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
7151726f ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
CancelPendingActions();
若要调用 CancelPendingActions，必须从 （ViewState*） 移动到 （CUserView*）此对象。 另请注意， CancelPendingActions 使用__thiscall调用约定，而不是__stdcall。 根据__thiscall，“this”指针在 ECX 寄存器中传递，而不是在堆栈上传递。
71517272 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
71517275 e832fbffff call CUserView::CancelPendingActions (71516dac) ; __thiscall
ReleaseAndNull(&_psf);
7151727a 33ff xor edi,edi ; edi = 0 (for later)
No_Psv:
7151727c 8d4678 lea eax,[esi+0x78] ; eax = &_psf
7151727f 50 push eax ; parameter
71517280 ffd3 call ebx ; call ReleaseAndNull
if (fViewObjectChanged)
71517282 397dfc cmp [ebp-0x4],edi ; fViewObjectChanged == 0?
71517285 740d jz NoNotifyViewClients (71517294) ; jump if zero
NotifyViewClients(DVASPECT_CONTENT, -1);
71517287 8b46ec mov eax,[esi-0x14] ; eax = ((CUserView*)this)->lpVtbl
7151728a 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
7151728d 6aff push 0xff ; -1
7151728f 6a01 push 0x1 ; DVASPECT_CONTENT = 1
71517291 ff5024 call [eax+0x24] ; __thiscall NotifyViewClients
NoNotifyViewClients:
if (m_pszTitle)
71517294 8b8680000000 mov eax,[esi+0x80] ; eax = m_pszTitle
7151729a 8d9e80000000 lea ebx,[esi+0x80] ; ebx = &m_pszTitle (for later)
715172a0 3bc7 cmp eax,edi ; eax == 0?
715172a2 7409 jz No_Title (715172ad) ; jump if zero
LocalFree(m_pszTitle);
715172a4 50 push eax ; m_pszTitle
715172a5 ff1538125071 call [_imp__LocalFree]
m_pszTitle = NULL;
请记住，EDI 仍然为零，EBX 仍为 &m_pszTitle，因为这些寄存器由函数调用保留。
715172ab 893b mov [ebx],edi ; m_pszTitle = 0
No_Title:
SetRect(&m_rcBounds, 0, 0, 0, 0);
715172ad 57 push edi ; 0
715172ae 57 push edi ; 0
715172af 57 push edi ; 0
715172b0 81c6fc000000 add esi,0xfc ; esi = &this->m_rcBounds
715172b6 57 push edi ; 0
715172b7 56 push esi ; &m_rcBounds
715172b8 ff15e41a5071 call [_imp__SetRect]
请注意，不再需要“this”的值，因此编译器使用 添加 指令来就地修改它，而不是使用另一个寄存器来保存地址。 实际上，由于奔腾 u/v 的管道设计，这是性能上的一次提升，因为 V 管道可以进行算术运算，但不能进行地址计算。
return S_OK;
715172be 33c0 xor eax,eax ; eax = S_OK
最后，还原需要保留的寄存器、清理堆栈并返回到调用方，删除传入参数。
715172c0 5b pop ebx ; restore
ReturnNoEBX:
715172c1 5f pop edi ; restore
715172c2 5e pop esi ; restore
715172c3 c9 leave ; restores EBP and ESP simultaneously
715172c4 c20400 ret 0x4 ; return and clear parameters