通过

创建轨迹（Transact-SQL）

本主题介绍如何使用存储过程创建跟踪。

创建跟踪

  1. 使用所需的参数执行 sp_trace_create 以创建新跟踪。 新跟踪将处于停止状态（状态 为 0）。

  2. 使用所需的参数执行 sp_trace_setevent 以选择要跟踪的事件和列。

  3. （可选）执行 sp_trace_setfilter 以设置任何筛选器或组合筛选器。

    sp_trace_setevent 和 sp_trace_setfilter 只能对停止的现有跟踪执行。

    重要

    与常规存储过程不同，所有 SQL Server Profiler 存储过程（sp_trace_xx）的参数都严格类型化，不支持自动数据类型转换。 如果未使用正确的输入参数数据类型调用这些参数，如参数说明中指定的，则存储过程将返回错误。

示例：

以下代码演示如何使用 Transact-SQL 创建跟踪。 它分为三个部分：创建跟踪、填充跟踪文件以及停止跟踪。 通过添加要跟踪的事件以自定义跟踪。 有关事件和列的列表，请参阅sp_trace_setevent（Transact-SQL）。

以下代码创建跟踪，将事件添加到跟踪，然后启动跟踪：

DECLARE @RC int, @TraceID int, @on BIT  
EXEC @rc = sp_trace_create @TraceID output, 0, N'C:\SampleTrace'  
  
-- Select the return code to see if the trace creation was successful.  
SELECT RC = @RC, TraceID = @TraceID  
  
-- Set the events and data columns you need to capture.  
SELECT @on = 1  
  
-- 10 is RPC:Completed event. 1 is TextData column.   
EXEC sp_trace_setevent @TraceID, 10, 1, @on   
-- 13 is SQL:BatchStarting, 11 is LoginName  
EXEC sp_trace_setevent @TraceID, 13, 11, @on   
-- 13 is SQL:BatchStarting, 14 is StartTime  
EXEC sp_trace_setevent @TraceID, 13, 14, @on   
-- 12 is SQL:BatchCompleted, 15 is EndTime  
EXEC sp_trace_setevent @TraceID, 12, 15, @on   
-- 13 is SQL:BatchStarting, 1 is TextData  
EXEC sp_trace_setevent @TraceID, 13, 1, @on   
  
-- Set any filter. Not provided in this example  
--EXEC sp_trace_setfilter 1, 10, 0, 6, N'%Profiler%'  
  
-- Start Trace (status 1 = start)  
EXEC @RC = sp_trace_setstatus @TraceID, 1  
GO

示例：

创建并启动跟踪后，请执行以下代码，使用活动填充跟踪。

SELECT * FROM master.sys.databases  
GO  
SELECT * FROM ::fn_trace_getinfo(default)  
GO

示例：

可以随时停止和重启跟踪。 在此示例中，执行以下代码以停止跟踪、关闭跟踪并删除跟踪定义。

DECLARE @TraceID int  
-- Populate a variable with the trace_id of the current trace  
SELECT  @TraceID = TraceID FROM ::fn_trace_getinfo(default) WHERE VALUE = N'C:\SampleTrace.trc'  
  
-- First stop the trace.   
EXEC sp_trace_setstatus @TraceID, 0  
  
-- Close and then delete its definition from SQL Server.   
EXEC sp_trace_setstatus @TraceID, 2

示例：

若要检查跟踪文件，请使用 SQL Server Profiler 打开 SampleTrace.trc 文件。

另请参阅

SQL Server Profiler 存储过程 (Transact-SQL)
sp_trace_create（Transact-SQL）
sp_trace_setevent（Transact-SQL）
sp_trace_setfilter（Transact-SQL）