语法
Table.RemoveMatchingRows(
table as table,
rows as list,
optional equationCriteria as any
) as table
关于
从表中删除所有指定的行。
-
table：要搜索的表。 -
rows：包含要删除的行的相关信息的列表。 -
equationCriteria：（可选） 指定比较值时如何确定相等性。 此参数可以是键选择器函数、比较器函数或表中要在比较行时使用的列的列表。
示例 1
从指定表中删除 [a = 1] 的任何行。
使用情况
Table.RemoveMatchingRows(
Table.FromRecords({
[a = 1, b = 2],
[a = 3, b = 4],
[a = 1, b = 6]
}),
{[a = 1]},
"a"
)
输出
Table.FromRecords({[a = 3, b = 4]})
示例 2
删除已取消的订单，忽略大小写。
使用情况
let
CurrentOrders = #table(type table[OrderID = number, Product = text, Quantity = number],
{
{101, "Widget", 5},
{102, "Gadget", 3},
{103, "Widget", 5}
}),
CanceledOrders = {
[OrderID = 103, Product = "widget", Quantity = 5]
},
FilteredOrders = Table.RemoveMatchingRows(CurrentOrders, CanceledOrders, Comparer.OrdinalIgnoreCase)
in
FilteredOrders
输出
#table(type table[OrderID = number, Product = text, Quantity = number],
{
{101, "Widget", 5},
{102, "Gadget", 3}
})
示例 3
删除美国假日下的任何维护任务。
使用情况
let
MaintenanceSchedule = #table(type table [Task = text, Date = date],
{
{"HVAC Check", #date(2025, 7, 10)}, // Not a holiday
{"Window Washing", #date(2025, 9, 1)}, // Labor Day
{"Fire Drill", #date(2025, 9, 17)}, // Not a holiday
{"Light Bulb Replacement", #date(2025, 11, 27)} // Thanksgiving
}),
USHolidays = {
[Date = #date(2025, 1, 1)], // New Year's Day
[Date = #date(2025, 7, 4)], // Independence Day
[Date = #date(2025, 9, 1)], // Labor Day
[Date = #date(2025, 11, 27)], // Thanksgiving
[Date = #date(2025, 12, 25)] // Christmas
},
FilteredSchedule = Table.RemoveMatchingRows(
MaintenanceSchedule,
USHolidays,
{"Date"}
)
in
FilteredSchedule
输出
#table(type table[Task = text, Date = date],
{
{"HVAC Check", #date(2025, 7, 10)},
{"Fire Drill", #date(2025, 9, 17)}
})