内插字符串

2025-10-17

内插字符串是允许将 F# 表达式嵌入其中的字符串。它们在各种情况下非常有用，其中字符串的值可能会根据值或表达式的结果而更改。

语法

$"string-text {expr}"
$"string-text %format-specifier{expr}"
$@"string-text {expr}"
@$"string-text {expr}"
$"""string-text {"embedded string literal"}"""
$$"""string-text %%format-specifier{{expr}}"""

注解

内插字符串允许在字符串文本内的“漏洞”中编写代码。下面是一个基本示例：

let name = "Phillip"
let age = 30
printfn $"Name: {name}, Age: {age}"

printfn $"I think {3.0 + 0.14} is close to {System.Math.PI}!"

每个 {} 大括号对之间的内容可以是任何 F# 表达式。

对于非类型内插字符串（不含格式说明符），表达式将使用 ToString() 该方法转换为字符串。如果表达式的计算结果 null为空字符串，则使用空字符串。

对于具有格式说明符（如 %s{expr} 或） %d{expr}的类型内插字符串，转换遵循为该特定格式说明符定义的规则。若要转义大括号对，请编写其中两个 {} ，如下所示：

let str = $"A pair of braces: {{}}"
// "A pair of braces: {}"

类型内插字符串

内插字符串还可以具有 F# 格式说明符来强制实施类型安全性。

let name = "Phillip"
let age = 30

printfn $"Name: %s{name}, Age: %d{age}"

// Error: type mismatch
printfn $"Name: %s{age}, Age: %d{name}"

在上一示例中，代码错误地传递 age 应位于何处 name 的值，反之亦然。由于内插字符串使用格式说明符，因此这是一个编译错误，而不是一个微妙的运行时 bug。

逐字内插字符串

F# 以两种方式支持逐字内插字符串：

使用 `$@` 或 `@$` 前缀

可以按任意顺序将内插前缀 $ 与逐字字符串前缀 @ 组合在一起。逐字字符串忽略转义序列（除了 "" 表示引号外），可以跨越多行。这在处理包含反斜杠和引号的文件路径或字符串时特别有用。

let name = "Alice"
let path = @"C:\Users\Alice\Documents"

// Using $@ prefix
printfn $@"User {name} has files in: {path}"

// Using @$ prefix (also valid)
printfn @$"User {name} has files in: {path}"

// Embedding quotes - use "" to represent a single "
let message = $@"He said ""{name}"" is here"

使用三引号

F# 还支持带有三引号的逐字内插字符串，以便无需转义即可嵌入字符串文本。

let age = 30

printfn $"""Name: {"Phillip"}, Age: %d{age}"""

格式说明符

格式说明符可以是 printf 样式或。NET 样式。 Printf 样式说明符是在大括号前用纯文本格式覆盖的说明符。例如：

let pi = $"%0.3f{System.Math.PI}"  // "3.142"
let code = $"0x%08x{43962}"  // "0x0000abba"

格式说明符 %A 对于生成结构化 F# 数据的诊断输出特别有用。

let data = [0..4]
let output = $"The data is %A{data}"  // "The data is [0; 1; 2; 3; 4]"

.NET 样式说明符是可在大括号内String.Format放置的那些可用:说明符。例如：

let pi = $"{System.Math.PI:N4}"  // "3.1416"
let now = $"{System.DateTime.UtcNow:``yyyyMMdd``}" // for example, "20220210"

如果为 .NET 样式说明符包含异常字符，然后可以使用双反杆对其进行转义：

let nowDashes = $"{System.DateTime.UtcNow:``yyyy-MM-dd``}" // for example, "2022-02-10"

在内插字符串中对齐表达式

可以在内插字符串 | 内左对齐或右对齐表达式，以及空格数的规范。以下内插字符串分别将左右表达式与左侧和右侧对齐 7 个空格。

printfn $"""|{"Left",-7}|{"Right",7}|"""
// |Left   |  Right|