Anteckning
Åtkomst till den här sidan kräver auktorisering. Du kan prova att logga in eller ändra kataloger.
Åtkomst till den här sidan kräver auktorisering. Du kan prova att ändra kataloger.
I följande avsnitt går vi igenom ett demonteringsexempel.
Källkod
Följande är koden för den funktion som ska analyseras.
HRESULT CUserView::CloseView(void)
{
if (m_fDestroyed) return S_OK;
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
if (m_psv) {
m_psb->EnableModelessSB(FALSE);
if(m_pws) m_pws->ViewReleased();
IShellView* psv;
HWND hwndCapture = GetCapture();
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
NotifyClients(m_psv, NOTIFY_CLOSING);
m_fRecursing = FALSE;
m_psv->UIActivate(SVUIA_DEACTIVATE);
psv = m_psv;
m_psv = NULL;
ReleaseAndNull(&_pctView);
if (m_pvo) {
IAdviseSink *pSink;
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
if (pSink == (IAdviseSink *)this)
m_pvo->SetAdvise(0, 0, NULL);
pSink->Release();
}
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
}
if (psv) {
psv->SaveViewState();
psv->DestroyViewWindow();
psv->Release();
}
m_hwndView = NULL;
m_fHandsOff = FALSE;
if (m_pcache) {
GlobalFree(m_pcache);
m_pcache = NULL;
}
m_psb->EnableModelessSB(TRUE);
CancelPendingActions();
}
ReleaseAndNull(&_psf);
if (fViewObjectChanged)
NotifyViewClients(DVASPECT_CONTENT, -1);
if (m_pszTitle) {
LocalFree(m_pszTitle);
m_pszTitle = NULL;
}
SetRect(&m_rcBounds, 0, 0, 0, 0);
return S_OK;
}
Sammansättningskod
Det här avsnittet innehåller det kommenterade exemplet på demontering.
Funktioner som använder ebp-registret som rampekare börjar på följande sätt:
HRESULT CUserView::CloseView(void)
SAMPLE!CUserView__CloseView:
71517134 55 push ebp
71517135 8bec mov ebp,esp
Detta konfigurerar ramen så att funktionen kan komma åt sina parametrar som positiva förskjutningar från ebp och lokala variabler som negativa förskjutningar.
Det här är en metod i ett privat COM-gränssnitt, så anropskonventionen är __stdcall. Det innebär att parametrarna skickas från höger till vänster (i det här fallet finns det inga), att pekaren "this" pushas och sedan anropas funktionen. När du kommer in i funktionen ser stacken alltså ut så här:
[esp+0] = return address
[esp+4] = this
Efter de två föregående instruktionerna är parametrarna tillgängliga som:
[ebp+0] = previous ebp pushed on stack
[ebp+4] = return address
[ebp+8] = this
För en funktion som använder ebp som rampekare är den första push-överförda parametern tillgänglig på [ebp+8]; efterföljande parametrar är tillgängliga vid på varandra följande högre DWORD-adresser.
71517137 51 push ecx
71517138 51 push ecx
Den här funktionen kräver bara två lokala stackvariabler, så en sub esp, 8 instruktion. Push-värdena är sedan tillgängliga som [ebp-4] och [ebp-8].
För en funktion som använder ebp som rampekare är stacklokala variabler tillgängliga vid negativa förskjutningar från ebp-registret .
71517139 56 push esi
Nu sparar kompilatorn de register som krävs för att bevaras mellan funktionsanrop. Faktiskt sparar den dem i bitar, sammanflätade med den första raden med faktisk kod.
7151713a 8b7508 mov esi,[ebp+0x8] ; esi = this
7151713d 57 push edi ; save another registers
CloseView är en metod på ViewState, vid offset 12 i det underliggande objektet. Det här är därför en pekare till en ViewState-klass, men när det finns en eventuell förvirring med en annan basklass anges den mer noggrant som (ViewState*)detta.
if (m_fDestroyed)
7151713e 33ff xor edi,edi ; edi = 0
XOR-operation av ett register med sig själv är en standardmetod för att nollställa det.
71517140 39beac000000 cmp [esi+0xac],edi ; this->m_fDestroyed == 0?
71517146 7407 jz NotDestroyed (7151714f) ; jump if equal
Cmp-instruktionen jämför två värden (genom att subtrahera dem). Jz-instruktionen kontrollerar om resultatet är noll, vilket anger att de två jämförde värdena är lika med.
Cmp-instruktionen jämför två värden; en efterföljande j-instruktion hoppar baserat på resultatet av jämförelsen.
return S_OK;
71517148 33c0 xor eax,eax ; eax = 0 = S_OK
7151714a e972010000 jmp ReturnNoEBX (715172c1) ; return, do not pop EBX
Kompilatorn fördröjde att spara EBX-registret till senare i funktionen, så om programmet ska avbryta tidigt på det här testet måste utgångsvägen vara den som inte återställer EBX.
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
Körningen av dessa två kodrader sker växelvis, så var uppmärksam.
NotDestroyed:
7151714f 8d86c0000000 lea eax,[esi+0xc0] ; eax = &m_pdtgt
Lea-instruktionen beräknar effektadressen för en minnesåtkomst och lagrar den i målet. Den faktiska minnesadressen är inte derefererad.
Lea-instruktionen tar adressen till en variabel.
71517155 53 push ebx
Du bör spara EBX-registret innan det skadas.
71517156 8b1d10195071 mov ebx,[_imp__ReleaseAndNull]
Eftersom du kommer att anropa ReleaseAndNull ofta är det en bra idé att cachelagra adressen i EBX.
7151715c 50 push eax ; parameter to ReleaseAndNull
7151715d 897dfc mov [ebp-0x4],edi ; fViewObjectChanged = FALSE
71517160 ffd3 call ebx ; call ReleaseAndNull
if (m_psv) {
71517162 397e74 cmp [esi+0x74],edi ; this->m_psv == 0?
71517165 0f8411010000 je No_Psv (7151727c) ; jump if zero
Kom ihåg att du nollställde EDI-registret för ett tag sedan och att EDI är ett register som bevaras mellan funktionsanrop (så anropet till ReleaseAndNull ändrade det inte). Därför innehåller den fortfarande värdet noll och du kan använda det för att snabbt testa för noll.
m_psb->EnableModelessSB(FALSE);
7151716b 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151716e 57 push edi ; FALSE
7151716f 50 push eax ; "this" for callee
71517170 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
71517172 ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
Ovanstående mönster är ett tecken på ett COM-metodanrop.
COM-metodanrop är ganska populära, så det är en bra idé att lära sig att känna igen dem. I synnerhet bör du kunna känna igen de tre IUnknown-metoderna direkt från deras Vtable-förskjutningar: QueryInterface=0, AddRef=4 och Release=8.
if(m_pws) m_pws->ViewReleased();
71517175 8b8614010000 mov eax,[esi+0x114] ; eax = this->m_pws
7151717b 3bc7 cmp eax,edi ; eax == 0?
7151717d 7406 jz NoWS (71517185) ; if so, then jump
7151717f 8b08 mov ecx,[eax] ; ecx = m_pws->lpVtbl
71517181 50 push eax ; "this" for callee
71517182 ff510c call [ecx+0xc] ; __stdcall ViewReleased
NoWS:
HWND hwndCapture = GetCapture();
71517185 ff15e01a5071 call [_imp__GetCapture] ; call GetCapture
Indirekta anrop via globaler är hur funktionsimporter implementeras i Microsoft Win32. Inläsaren åtgärdar de globala variablerna så att de pekar på den faktiska adressen till målet. Det här är ett praktiskt sätt att orientera sig när du undersöker en kraschad maskin. Leta efter anrop till importerade funktioner och i målmiljön. Du har vanligtvis namnet på en importerad funktion som du kan använda för att avgöra var du befinner dig i källkoden.
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
7151718b 3bc7 cmp eax,edi ; hwndCapture == 0?
7151718d 7412 jz No_Capture (715171a1) ; jump if zero
Funktionens returvärde placeras i EAX-registret.
7151718f 8b4e44 mov ecx,[esi+0x44] ; ecx = this->m_hwnd
71517192 3bc1 cmp eax,ecx ; hwndCapture = ecx?
71517194 750b jnz No_Capture (715171a1) ; jump if not
71517196 57 push edi ; 0
71517197 57 push edi ; 0
71517198 6a1f push 0x1f ; WM_CANCELMODE
7151719a 51 push ecx ; hwndCapture
7151719b ff1518195071 call [_imp__SendMessageW] ; SendMessage
No_Capture:
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
715171a1 66818e0c0100000180 or word ptr [esi+0x10c],0x8001 ; set both flags at once
NotifyClients(m_psv, NOTIFY_CLOSING);
715171aa 8b4e20 mov ecx,[esi+0x20] ; ecx = (CNotifySource*)this.vtbl
715171ad 6a04 push 0x4 ; NOTIFY_CLOSING
715171af 8d4620 lea eax,[esi+0x20] ; eax = (CNotifySource*)this
715171b2 ff7674 push [esi+0x74] ; m_psv
715171b5 50 push eax ; "this" for callee
715171b6 ff510c call [ecx+0xc] ; __stdcall NotifyClients
Observera hur du var tvungen att ändra din "detta"-pekare när du anropade en metod i en annan basklass än din egen.
m_fRecursing = FALSE;
715171b9 80a60d0100007f and byte ptr [esi+0x10d],0x7f
m_psv->UIActivate(SVUIA_DEACTIVATE);
715171c0 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171c3 57 push edi ; SVUIA_DEACTIVATE = 0
715171c4 50 push eax ; "this" for callee
715171c5 8b08 mov ecx,[eax] ; ecx = vtbl
715171c7 ff511c call [ecx+0x1c] ; __stdcall UIActivate
psv = m_psv;
m_psv = NULL;
715171ca 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171cd 897e74 mov [esi+0x74],edi ; m_psv = NULL
715171d0 8945f8 mov [ebp-0x8],eax ; psv = eax
Den första lokala variabeln är psv.
ReleaseAndNull(&_pctView);
715171d3 8d466c lea eax,[esi+0x6c] ; eax = &_pctView
715171d6 50 push eax ; parameter
715171d7 ffd3 call ebx ; call ReleaseAndNull
if (m_pvo) {
715171d9 8b86a8000000 mov eax,[esi+0xa8] ; eax = m_pvo
715171df 8dbea8000000 lea edi,[esi+0xa8] ; edi = &m_pvo
715171e5 85c0 test eax,eax ; eax == 0?
715171e7 7448 jz No_Pvo (71517231) ; jump if zero
Observera att kompilatorn proaktivt förberedde adressen till m_pvo-medlemmen, eftersom du kommer att använda den ofta under en tid. Därför resulterar det i mindre kod att ha adressen tillgänglig.
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
715171e9 8b08 mov ecx,[eax] ; ecx = m_pvo->lpVtbl
715171eb 8d5508 lea edx,[ebp+0x8] ; edx = &pSink
715171ee 52 push edx ; parameter
715171ef 6a00 push 0x0 ; NULL
715171f1 6a00 push 0x0 ; NULL
715171f3 50 push eax ; "this" for callee
715171f4 ff5120 call [ecx+0x20] ; __stdcall GetAdvise
715171f7 85c0 test eax,eax ; test bits of eax
715171f9 7c2c jl No_Advise (71517227) ; jump if less than zero
715171fb 33c9 xor ecx,ecx ; ecx = 0
715171fd 394d08 cmp [ebp+0x8],ecx ; _pSink == ecx?
71517200 7425 jz No_Advise (71517227)
Observera att kompilatorn drog slutsatsen att den inkommande parametern "den här" inte krävdes (eftersom den för länge sedan gömde den i ESI-registret). Därför återanvände den minnet som den lokala variabeln pSink.
Om funktionen använder en EBP-ramstruktur får inkommande parametrar positiva förskjutningar från EBP och lokala variabler placeras vid negativa förskjutningar. Men som i det här fallet är kompilatorn fri att återanvända minnet för alla ändamål.
Om du är uppmärksam ser du att kompilatorn kunde ha optimerat koden lite bättre. Det kunde ha försenat lea edi, [esi+0xa8]-instruktionen tills efter de två push 0x0-instruktionerna, för att sedan ersätta dem med push edi. Detta skulle ha sparat 2 byte.
if (pSink == (IAdviseSink *)this)
Nästa flera rader är för att kompensera för det faktum att i C++ måste (IAdviseSink *)NULL fortfarande vara NULL. Så om "detta" verkligen är "(ViewState*)NULL" ska resultatet av casten vara NULL och inte avståndet mellan IAdviseSink och IBrowserService.
71517202 8d46ec lea eax,[esi-0x14] ; eax = -(IAdviseSink*)this
71517205 8d5614 lea edx,[esi+0x14] ; edx = (IAdviseSink*)this
71517208 f7d8 neg eax ; eax = -eax (sets carry if != 0)
7151720a 1bc0 sbb eax,eax ; eax = eax - eax - carry
7151720c 23c2 and eax,edx ; eax = NULL or edx
Även om Pentium har en instruktion för villkorsstyrd flytt gör inte basarkitekturen i386 det, så kompilatorn använder specifika tekniker för att simulera en instruktion för villkorlig flytt utan att ta några hopp.
Det allmänna mönstret för en villkorsstyrd utvärdering är följande:
neg r
sbb r, r
and r, (val1 - val2)
add r, val2
Neg r anger bärflaggan om r inte är noll, eftersom neg neggerar värdet genom att subtrahera från noll. Subtraherar du från noll uppstår ett lån (sätta bäring) om du subtraherar ett icke-nollvärde. Det skadar också värdet i r-registret , men det är acceptabelt eftersom du är på väg att skriva över det ändå.
Därefter subtraherar instruktionen sbb r, r ett värde från sig själv, vilket alltid resulterar i noll. Men den subtraherar också bärbiten (lånbiten), så slutresultatet blir att sätta r till noll eller -1, beroende på om bärbiten var nollställd eller satt.
Därför anger sbb r, rr till noll om det ursprungliga värdet för r var noll eller till -1 om det ursprungliga värdet inte var noll.
Den tredje instruktionen utför en mask. Eftersom r-registret är noll eller -1 tjänar "detta" antingen till att lämna r noll eller att ändra r från -1 till (val1 - val1), i det att ANDing alla värden med -1 lämnar det ursprungliga värdet.
Därför är resultatet av "och r, (val1 - val1)" att ange r till noll om det ursprungliga värdet för r var noll, eller till "(val1 - val2)" om det ursprungliga värdet för r var nonzero.
Slutligen lägger du till val2 i r, vilket resulterar i val2 eller (val1 - val2) + val2 = val1.
Det slutliga resultatet av den här serien med instruktioner är därför att ange r till val2 om det ursprungligen var noll eller val1 om det inte var noll. Det här är sammansättningsekvivalenten för r = r ? val1 : val2.
I den här specifika instansen kan du se att val2 = 0 och val1 = (IAdviseSink*)detta. (Observera att kompilatorn utelämnade den sista add eax, 0-instruktionen eftersom den inte har någon effekt.)
7151720e 394508 cmp [ebp+0x8],eax ; pSink == (IAdviseSink*)this?
71517211 750b jnz No_SetAdvise (7151721e) ; jump if not equal
Tidigare i det här avsnittet angav du EDI till adressen för den m_pvo medlemmen. Du kommer att använda det nu. Du nollställde också ECX-registret tidigare.
m_pvo->SetAdvise(0, 0, NULL);
71517213 8b07 mov eax,[edi] ; eax = m_pvo
71517215 51 push ecx ; NULL
71517216 51 push ecx ; 0
71517217 51 push ecx ; 0
71517218 8b10 mov edx,[eax] ; edx = m_pvo->lpVtbl
7151721a 50 push eax ; "this" for callee
7151721b ff521c call [edx+0x1c] ; __stdcall SetAdvise
No_SetAdvise:
pSink->Release();
7151721e 8b4508 mov eax,[ebp+0x8] ; eax = pSink
71517221 50 push eax ; "this" for callee
71517222 8b08 mov ecx,[eax] ; ecx = pSink->lpVtbl
71517224 ff5108 call [ecx+0x8] ; __stdcall Release
No_Advise:
Alla dessa COM-metodanrop bör se mycket bekanta ut.
Utvärderingen av de kommande två uttalandena sker omväxlande. Glöm inte att EBX innehåller adressen till ReleaseAndNull.
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
71517227 57 push edi ; &m_pvo
71517228 c745fc01000000 mov dword ptr [ebp-0x4],0x1 ; fViewObjectChanged = TRUE
7151722f ffd3 call ebx ; call ReleaseAndNull
No_Pvo:
if (psv) {
71517231 8b7df8 mov edi,[ebp-0x8] ; edi = psv
71517234 85ff test edi,edi ; edi == 0?
71517236 7412 jz No_Psv2 (7151724a) ; jump if zero
psv->SaveViewState();
71517238 8b07 mov eax,[edi] ; eax = psv->lpVtbl
7151723a 57 push edi ; "this" for callee
7151723b ff5034 call [eax+0x34] ; __stdcall SaveViewState
Här är fler COM-metodanrop.
psv->DestroyViewWindow();
7151723e 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517240 57 push edi ; "this" for callee
71517241 ff5028 call [eax+0x28] ; __stdcall DestroyViewWindow
psv->Release();
71517244 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517246 57 push edi ; "this" for callee
71517247 ff5008 call [eax+0x8] ; __stdcall Release
No_Psv2:
m_hwndView = NULL;
7151724a 83667c00 and dword ptr [esi+0x7c],0x0 ; m_hwndView = 0
ANDing en minnesplats med noll är detsamma som att ställa in den på noll, eftersom allt OCH noll är noll. Kompilatorn använder det här formuläret eftersom det, även om det är långsammare, är mycket kortare än motsvarande mov-instruktion . (Den här koden har optimerats för storlek, inte hastighet.)
m_fHandsOff = FALSE;
7151724e 83a60c010000fe and dword ptr [esi+0x10c],0xfe
if (m_pcache) {
71517255 8b4670 mov eax,[esi+0x70] ; eax = m_pcache
71517258 85c0 test eax,eax ; eax == 0?
7151725a 740b jz No_Cache (71517267) ; jump if zero
GlobalFree(m_pcache);
7151725c 50 push eax ; m_pcache
7151725d ff15b4135071 call [_imp__GlobalFree] ; call GlobalFree
m_pcache = NULL;
71517263 83667000 and dword ptr [esi+0x70],0x0 ; m_pcache = 0
No_Cache:
m_psb->EnableModelessSB(TRUE);
71517267 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151726a 6a01 push 0x1 ; TRUE
7151726c 50 push eax ; "this" for callee
7151726d 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
7151726f ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
CancelPendingActions();
För att kunna anropa CancelPendingActions måste du flytta från (ViewState*)till (CUserView*)detta. Observera också att CancelPendingActions använder __thiscall-anropskonventionen i stället för __stdcall. Enligt __thiscall skickas pekaren "den här" i ECX-registret i stället för att skickas på stacken.
71517272 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
71517275 e832fbffff call CUserView::CancelPendingActions (71516dac) ; __thiscall
ReleaseAndNull(&_psf);
7151727a 33ff xor edi,edi ; edi = 0 (for later)
No_Psv:
7151727c 8d4678 lea eax,[esi+0x78] ; eax = &_psf
7151727f 50 push eax ; parameter
71517280 ffd3 call ebx ; call ReleaseAndNull
if (fViewObjectChanged)
71517282 397dfc cmp [ebp-0x4],edi ; fViewObjectChanged == 0?
71517285 740d jz NoNotifyViewClients (71517294) ; jump if zero
NotifyViewClients(DVASPECT_CONTENT, -1);
71517287 8b46ec mov eax,[esi-0x14] ; eax = ((CUserView*)this)->lpVtbl
7151728a 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
7151728d 6aff push 0xff ; -1
7151728f 6a01 push 0x1 ; DVASPECT_CONTENT = 1
71517291 ff5024 call [eax+0x24] ; __thiscall NotifyViewClients
NoNotifyViewClients:
if (m_pszTitle)
71517294 8b8680000000 mov eax,[esi+0x80] ; eax = m_pszTitle
7151729a 8d9e80000000 lea ebx,[esi+0x80] ; ebx = &m_pszTitle (for later)
715172a0 3bc7 cmp eax,edi ; eax == 0?
715172a2 7409 jz No_Title (715172ad) ; jump if zero
LocalFree(m_pszTitle);
715172a4 50 push eax ; m_pszTitle
715172a5 ff1538125071 call [_imp__LocalFree]
m_pszTitle = NULL;
Kom ihåg att EDI fortfarande är noll och att EBX fortfarande är &m_pszTitle, eftersom dessa register bevaras av funktionsanrop.
715172ab 893b mov [ebx],edi ; m_pszTitle = 0
No_Title:
SetRect(&m_rcBounds, 0, 0, 0, 0);
715172ad 57 push edi ; 0
715172ae 57 push edi ; 0
715172af 57 push edi ; 0
715172b0 81c6fc000000 add esi,0xfc ; esi = &this->m_rcBounds
715172b6 57 push edi ; 0
715172b7 56 push esi ; &m_rcBounds
715172b8 ff15e41a5071 call [_imp__SetRect]
Observera att du inte behöver värdet för "detta" längre, så kompilatorn använder instruktionen lägg till för att ändra det på plats i stället för att använda ett annat register för att lagra adressen. Det är faktiskt en prestandafördel på grund av Pentium u/v-pipelining, eftersom v-pipelinen kan utföra aritmetiska operationer, men inte adressberäkningar.
return S_OK;
715172be 33c0 xor eax,eax ; eax = S_OK
Slutligen återställer du de register som du måste bevara, rensa stacken och återgå till anroparen och ta bort de inkommande parametrarna.
715172c0 5b pop ebx ; restore
ReturnNoEBX:
715172c1 5f pop edi ; restore
715172c2 5e pop esi ; restore
715172c3 c9 leave ; restores EBP and ESP simultaneously
715172c4 c20400 ret 0x4 ; return and clear parameters