Självstudie: Koppla data från flera tabeller

Gäller för: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Genom att koppla data från flera tabeller kan du analysera data mellan källor och skapa relationer mellan datapunkter. I KQL (Kusto Query Language) använder du kopplings - och uppslagsoperatorerna för att kombinera data mellan tabeller.

I den här tutorialen lär du dig följande:

Förutsättningar

Kör frågorna i en frågemiljö som har åtkomst till exempeldata. Använd något av följande:

Använd kopplingsoperatorn

Exempeldatabasen har två relaterade stormhändelsetabeller: StormEvents och PopulationData. I det här avsnittet ansluter du dem för att analysera data som inte är möjliga enbart med en tabell.

Förstå data

Använd operatorn ta för att se vilka data varje tabell innehåller.

StormEvents 
| take 5

Följande tabell visar bara sex av de 22 returnerade kolumnerna.

PopulationData 
| take 5

utdata

Båda tabellerna har en State kolumn. StormEvents har många fler kolumner och PopulationData har en annan kolumn med delstatens population.

Sammanfoga tabellerna

Anslut PopulationData till StormEvents på State för att beräkna den totala egendomsskadan per capita efter delstat.

StormEvents
| summarize PropertyDamage = sum(DamageProperty) by State
| join kind=innerunique PopulationData on State
| project State, PropertyDamagePerCapita = PropertyDamage / Population
| sort by PropertyDamagePerCapita

Lägg till | render columnchart i frågan för att visualisera resultatet.

Om kolumnerna har olika namn (till exempel StormEvents har State och PopulationData har StateName), anger du kopplingen som:

StormEvents
| join kind=innerunique PopulationData on $left.State == $right.StateName  

$left refererar till den vänstra tabellen (yttre) i kopplingen: StormEvents. $right refererar till den högra (inre) tabellen: PopulationData.

Använda uppslagsoperatorn

Uppslagsoperatorn optimerar frågor som berikar en faktatabell med data från en dimensionstabell. Den utökar faktatabellen med värden från dimensionstabellen. Systemet förutsätter som standard att den vänstra tabellen är den större faktatabellen och att den högra tabellen är den mindre dimensionstabellen. Den här standardinställningen är motsatsen till join operatorns antagande.

Hjälpklustret innehåller en databas med namnet ContosoSales med försäljningsdata. Följande fråga använder lookup för att sammanfoga tabellerna SalesFact och Products för att returnera total försäljning efter produktkategori.

SalesFact
| lookup Products on ProductKey
| summarize TotalSales = count() by ProductCategoryName
| order by TotalSales desc

utdata

Ansluta till frågegenererade tabeller

Koppla resultat från samma tabell.

Anta att du vill ha en lista över tillstånd som har både blixt- och lavinhändelser. Använd kopplingsoperatorn för att sammanfoga rader från två frågor som returnerar distinkta tillstånd för varje händelsetyp i State kolumnen.

StormEvents
| where EventType == "Lightning"
| distinct State
| join kind=inner (
    StormEvents 
    | where EventType == "Avalanche"
    | distinct State
    )
    on State
| project State

utdata

Relaterat innehåll

• Lär dig mer om olika typer av kopplingsoperatorer.
• Utför frågor mellan databaser och kluster.
• Följ handledningen Skapa geospatiala visualiseringar.