mv-expand operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Expanderar dynamiska matriser med flera värden eller egenskapspåsar till flera poster.

mv-expand can be described as the opposite of the aggregation operators that pack multiple values into a single dynamic-typed array or property bag, such as summarize ... make-list() and make-series. Varje element i matrisen (skalär) eller egenskapspåsen genererar en ny post i operatorns utdata. Alla kolumner i indata som inte expanderas dupliceras till alla poster i utdata.

Syntax

T|mv-expand [kind=(bag | array)] [with_itemindex=IndexColumnName] ColumnName [to typeof(Typename)] [,ColumnName ...] [limitRowlimit]

T|mv-expand [kind=(bag | array)] [Name=] ArrayExpression [to typeof(Typename)] [, [Name=] ArrayExpression [to typeof(Typename)] ...] [limitRowlimit]

Learn more about syntax conventions.

Parameters

Returns

För varje post i indata returnerar operatorn noll, en eller flera poster i utdata, enligt följande:

1. Indatakolumner som inte expanderas visas i utdata med sitt ursprungliga värde. Om en enskild indatapost expanderas till flera utdataposter dupliceras värdet till alla poster.

2. For each ColumnName or ArrayExpression that is expanded, the number of output records is determined for each value as explained in modes of expansion. För varje indatapost beräknas det maximala antalet utdataposter. Alla matriser eller egenskapspåsar expanderas "parallellt" så att saknade värden (om några) ersätts med null-värden. Element expanderas till rader i den ordning de visas i den ursprungliga matrisen/påsen.

3. Om det dynamiska värdet är null skapas en enskild post för det värdet (null). Om det dynamiska värdet är en tom matris eller egenskapspåse skapas ingen post för det värdet. Annars skapas lika många poster som det finns element i det dynamiska värdet.

De expanderade kolumnerna är av typen dynamic, såvida de inte uttryckligen skrivs med hjälp av to typeof()-satsen.

Expansionslägen

Två lägen för expansioner av egenskapsväskan stöds:

• kind=bag eller bagexpansion=bag: Egenskapspåsar utökas till enstaka egenskapspåsar. Det här läget är standardläget.
• kind=array or bagexpansion=array: Property bags are expanded into two-element [key,value] array structures, allowing uniform access to keys and values. I det här läget kan du till exempel köra en distinkt sammansättning över egenskapsnamn.

Examples

Exemplen i det här avsnittet visar hur du använder syntaxen för att komma igång.

En kolumn – matrisexpansion

datatable (a: int, b: dynamic)
[
    1, dynamic([10, 20]),
    2, dynamic(['a', 'b'])
]
| mv-expand b

Output

Enkel kolumn – påsexpansion

En enkel expansion av en enskild kolumn:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand b

Output

Enkel kolumn – påsexpansion till nyckel/värde-par

En enkel påse-expansion till nyckel/värde-par:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand kind=array b 
| extend key = b[0], val=b[1]

Output

Zippade två kolumner

Expandera två kolumner först "zip" de tillämpliga kolumnerna och expandera dem sedan:

datatable (a: int, b: dynamic, c: dynamic)[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 4, 3])
]
| mv-expand b, c

Output

Kartesisk produkt av två kolumner

Om du vill få en kartesisk produkt av att expandera två kolumner expanderar du en efter en:

datatable (a: int, b: dynamic, c: dynamic)
[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 6])
]
| mv-expand b
| mv-expand c

Output

Convert output

Om du vill tvinga utdata från en mv-expandering till en viss typ (standardvärdet är dynamiskt) använder du to typeof:

datatable (a: string, b: dynamic, c: dynamic)[
    "Constant", dynamic([1, 2, 3, 4]), dynamic([6, 7, 8, 9])
]
| mv-expand b, c to typeof(int)
| getschema 

Output

Meddelandekolumnen b returneras som dynamic medan c returneras som int.

Using with_itemindex

Expansion av en matris med with_itemindex:

range x from 1 to 4 step 1
| summarize x = make_list(x)
| mv-expand with_itemindex=Index x

Output