Geospatiala visualiseringar

Gäller för: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Geospatiala data kan visualiseras som en del av din fråga med återgivningsoperatorn som punkter, cirkel eller bubblor på en karta.

Mer information om geospatial klustring finns i Geospatial klustring.

Exempel

I följande exempel hittar du stormhändelser och visualiserar 100 på en karta.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

I följande exempel visualiseras flera serier med punkter, där paret [Longitude, Latitude] definierar varje punkt och en tredje kolumn definierar serien. I det här exemplet är EventTypeserien .

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

I följande exempel visualiseras en serie punkter på en karta. Om du har flera kolumner i resultatet måste du ange vilka kolumner som ska användas för xcolumn (longitud), ycolumn (latitud) och serier.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

I följande exempel visualiseras punkter på kartan med hjälp av dynamiska GeoJSON-värden för att definiera punkterna.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

I följande exempel visas stormhändelser aggregerade av S2-celler. Diagrammet aggregerar händelser i bubblor efter plats i en färg.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

I följande exempel visas stormhändelser aggregerade av S2-celler. Diagrammet aggregerar händelser efter händelsetyp i cirkeldiagram efter plats.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Relaterat innehåll

• Geospatial klustring
• Rendera operator
• Dataanalys för fordonstestflottor (geospatial klustringsanvändning)
• Lär dig mer om Azure-arkitektur för geospatial databearbetning och analys