bin()

Gäller för: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Avrundar värden nedåt till en heltalsmultipel av en viss lagerplatsstorlek.

Används ofta i kombination med summarize by .... Om du har en punktspridd uppsättning värden grupperas de i en mindre uppsättning specifika värden.

Funktionerna bin() och floor() är likvärdiga

Syntax

bin( värde,roundTo)

Läs mer om syntaxkonventioner.

Parameterar

Retur

Den närmaste multipeln av roundTo under värdet. Null-värden, en null-bin-storlek eller en negativ bin-storlek resulterar i null.

Exempel

I följande exempel visas funktionen bin() med numeriska data.

print bin(4.5, 1)

Resultat

I följande exempel visas funktionen bin() med tidsintervalldata.

print bin(time(16d), 7d)

Resultat

I följande exempel visas funktionen bin() med datetime-data.

print bin(datetime(1970-05-11 13:45:07), 1d)

Resultat

När det finns rader för lagerplatser utan motsvarande rad i tabellen rekommenderar vi att du fyller tabellen med dessa lagerplatser. Följande fråga tittar på starka stormhändelser i Kalifornien under en vecka i april. Det finns dock inga händelser på vissa dagar.

let Start = datetime('2007-04-07');
let End = Start + 7d;
StormEvents
| where StartTime between (Start .. End)
| where State == "CALIFORNIA" and EventType == "Strong Wind"
| summarize PropertyDamage=sum(DamageProperty) by bin(StartTime, 1d)

Resultat

För att representera hela veckan fyller följande fråga resultattabellen med null-värden för de dagar som saknas. Här är en stegvis förklaring av processen:

1. Använd operatorn union för att lägga till fler rader i tabellen.
2. Operatorn range skapar en tabell som har en enda rad och kolumn.
3. Operatorn mv-expand över range funktionen skapar så många rader som det finns lagerplatser mellan StartTime och EndTime.
4. Använd en PropertyDamage av 0.
5. Operatorn summarize grupperar lagerplatser från den ursprungliga tabellen till tabellen som skapas av union uttrycket. Den här processen säkerställer att utdata har en rad per lagerplats vars värde antingen är noll eller det ursprungliga antalet.

let Start = datetime('2007-04-07');
let End = Start + 7d;
StormEvents
| where StartTime between (Start .. End)
| where State == "CALIFORNIA" and EventType == "Strong Wind"
| union (
    range x from 1 to 1 step 1
    | mv-expand StartTime=range(Start, End, 1d) to typeof(datetime)
    | extend PropertyDamage=0
    )
| summarize PropertyDamage=sum(DamageProperty) by bin(StartTime, 1d)

Resultat