Dela via

Använda varians för Func och Action – Generiska Delegater (Visual Basic)

Dessa exempel demonstrerar hur man använder samvarians och kontravarians i de generiska delegaterna Func och Action för att möjliggöra återanvändning av metoder och ge mer flexibilitet i din kod.

Mer information om kovarians och kontravarians finns i Varians i Delegater (Visual Basic).

Använda delegater med covarianta typparametrar

I följande exempel illustreras fördelarna med kovariansstöd i de generiska Func delegaterna. Metoden FindByTitle tar en parameter av typen String och returnerar ett objekt av typen Employee . Du kan dock tilldela den här metoden till ombudet Func(Of String, Person) eftersom Employee ärver Person.

' Simple hierarchy of classes.
Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class Finder
    Public Shared Function FindByTitle(
        ByVal title As String) As Employee
        ' This is a stub for a method that returns
        ' an employee that has the specified title.
        Return New Employee
    End Function

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim findEmployee As Func(Of String, Employee) =
            AddressOf FindByTitle

        ' The delegate expects a method to return Person,
        ' but you can assign it a method that returns Employee.
        Dim findPerson As Func(Of String, Person) =
            AddressOf FindByTitle

        ' You can also assign a delegate
        ' that returns a more derived type to a delegate
        ' that returns a less derived type.
        findPerson = findEmployee
    End Sub
End Class

Använda delegater med parametrar av typen Contravariant

I följande exempel illustreras fördelarna med kontravariansstöd i de generiska Action delegaterna. Metoden AddToContacts tar en parameter av typen Person . Du kan dock tilldela den här metoden till ombudet Action(Of Employee) eftersom Employee ärver Person.

Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class AddressBook
    Shared Sub AddToContacts(ByVal person As Person)
        ' This method adds a Person object
        ' to a contact list.
    End Sub

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim addPersonToContacts As Action(Of Person) =
            AddressOf AddToContacts

        ' The Action delegate expects
        ' a method that has an Employee parameter,
        ' but you can assign it a method that has a Person parameter
        ' because Employee derives from Person.
        Dim addEmployeeToContacts As Action(Of Employee) =
            AddressOf AddToContacts

        ' You can also assign a delegate
        ' that accepts a less derived parameter
        ' to a delegate that accepts a more derived parameter.
        addEmployeeToContacts = addPersonToContacts
    End Sub
End Class

Se även