range operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Genererar en tabell med en kolumn med värden.

Syntax

range columnNamefromstarttostopstepstep

Learn more about syntax conventions.

Parameters

Returns

A table with a single column called columnName, whose values are start, start+step, ... up to and until stop.

Examples

Exemplet i det här avsnittet visar hur du använder syntaxen för att komma igång.

Intervall under de senaste sju dagarna

I följande exempel skapas en tabell med poster för den aktuella tidsstämpeln som har utökats under de senaste sju dagarna, en gång om dagen.

range LastWeek from ago(7d) to now() step 1d

Output

Kombinera olika stopptider

I följande exempel visas hur du utökar intervall för att använda flera stopptider med hjälp av operatorn union.

let Range1 = range Time from datetime(2024-01-01) to datetime(2024-01-05) step 1d;
let Range2 = range Time from datetime(2024-01-06) to datetime(2024-01-10) step 1d;
union Range1, Range2
| order by Time asc

Output

Intervall med parametrar

I följande exempel visas hur du använder operatorn range med parametrar, som sedan utökas och används som en tabell.

let toUnixTime = (dt:datetime) 
{ 
    (dt - datetime(1970-01-01)) / 1s 
};
let MyMonthStart = startofmonth(now()); //Start of month
let StepBy = 4.534h; //Supported timespans
let nn = 64000; // Row Count parametrized
let MyTimeline = range MyMonthHour from MyMonthStart to now() step StepBy
| extend MyMonthHourinUnixTime = toUnixTime(MyMonthHour), DateOnly = bin(MyMonthHour,1d), TimeOnly = MyMonthHour - bin(MyMonthHour,1d)
; MyTimeline | order by MyMonthHour asc | take nn

Output

Incremented steps

I följande exempel skapas en tabell med en enda kolumn med namnet Steps vars typ är long och resulterar i värden från en till åtta inkrementerade med tre.

range Steps from 1 to 8 step 3

Output

Spårningar över ett tidsintervall

I följande exempel visas hur range-operatorn kan användas för att skapa en dimensionstabell som används för att introducera nollor där källdata inte har några värden. Det tar tidsstämplar från de senaste fyra timmarna och räknar spårningar för varje intervall på en minut. När det inte finns några spårningar för ett visst intervall är antalet noll.

range TIMESTAMP from ago(4h) to now() step 1m
| join kind=fullouter
  (Traces
      | where TIMESTAMP > ago(4h)
      | summarize Count=count() by bin(TIMESTAMP, 1m)
  ) on TIMESTAMP
| project Count=iff(isnull(Count), 0, Count), TIMESTAMP
| render timechart