Dela via

Snabbstart: Distribuera din första Azure-uppdateringsresurs med AzAPI Terraform-providern

Artikel testad med följande Terraform- och Terraform-providerversioner:

Terraform möjliggör definition, förhandsversion och distribution av molninfrastruktur. Med Terraform skapar du konfigurationsfiler med hjälp av HCL-syntax. Med HCL-syntaxen kan du ange molnleverantören – till exempel Azure – och de element som utgör din molninfrastruktur. När du har skapat konfigurationsfilerna skapar du en körningsplan som gör att du kan förhandsgranska ändringarna i infrastrukturen innan de distribueras. När du har verifierat ändringarna tillämpar du genomförandeplanen för att implementera infrastrukturen.

I den här artikeln får du lära dig hur du använder AzAPI Terraform-providern för att hantera en ny funktion i en Azure-tjänst som för närvarande inte stöds av AzureRM-providern. azapi_update_resource Kommer att användas för att hantera en Azure EventHub-nätverksregeluppsättning.

  • Definiera och konfigurera AzureRM- och AzAPI-providers
  • Generera ett slumpmässigt namn för Event Hubs-namnområdet
  • Använd AzureRM-providern för att skapa en Azure-resursgrupp och nödvändiga nätverks- och Event Hubs-resurser
  • Använd AzAPI-providern för att lägga till en nätverksregeluppsättning till azurerm_eventhub_namespace resurserna

Anmärkning

Exempelkoden i den här artikeln finns på Azure Terraform GitHub-lagringsplatsen.

Förutsättningar

  • Azure-prenumeration: Om du inte har en Azure-prenumeration skapar du ett kostnadsfritt konto innan du börjar.

Utför implementeringen av Terraform-koden

  1. Skapa en katalog där du kan testa Terraform-exempelkoden och göra den till den aktuella katalogen.

  2. Skapa en fil med namnet providers.tf och infoga följande kod:

    terraform {
  required_providers {
    azapi = {
      source  = "azure/azapi"
      version = "=0.1.0"
    }

    azurerm = {
      source  = "hashicorp/azurerm"
      version = "=3.0.2"
    }

    random = {
      source  = "hashicorp/random"
      version = "=3.1.2"
    }
  }
}

provider "azapi" {
}

provider "azurerm" {
  features {}
}

provider "random" {
}

  3. Skapa en fil med namnet main.tf och infoga följande kod:

    resource "azurerm_resource_group" "qs101" {
  name     = "rg-qs101-eh-rules"
  location = "westus2"
}

resource "azurerm_virtual_network" "qs101" {
  name                = "myvnet"
  location            = azurerm_resource_group.qs101.location
  resource_group_name = azurerm_resource_group.qs101.name
  address_space       = ["172.17.0.0/16"]
  dns_servers         = ["10.0.0.4", "10.0.0.5"]
}

resource "azurerm_subnet" "qs101" {
  name                 = "default"
  resource_group_name  = azurerm_resource_group.qs101.name
  virtual_network_name = azurerm_virtual_network.qs101.name
  address_prefixes     = ["172.17.0.0/24"]

  service_endpoints = ["Microsoft.EventHub"]
}

resource "random_pet" "qs101_namespace" {
  length    = 3
  separator = ""
}

resource "azurerm_eventhub_namespace" "qs101" {
  name                = random_pet.qs101_namespace.id
  location            = azurerm_resource_group.qs101.location
  resource_group_name = azurerm_resource_group.qs101.name
  sku                 = "Standard"
  capacity            = 2
}

  4. Skapa en fil med namnet main-generic.tf och infoga följande kod:

    # AzAPI update resource is used to enable Network Rule sets on Event Hub namespace
resource "azapi_update_resource" "qs101" {
  type      = "Microsoft.EventHub/namespaces/networkRuleSets@2021-11-01"
  name      = "default"
  parent_id = azurerm_eventhub_namespace.qs101.id

  body = jsonencode({
    properties = {
      defaultAction       = "Deny"
      publicNetworkAccess = "Enabled"
      virtualNetworkRules = [
        {
          ignoreMissingVnetServiceEndpoint = false
          subnet = {
            # API bug, returned id replaced `resourceGroups` with `resourcegroups`
            id = replace(azurerm_subnet.qs101.id, "resourceGroups", "resourcegroups")
          }
        }
      ]
      ipRules = [
        {
          action = "Allow"
          ipMask = "1.1.1.1"
        }
      ]
    }
  })
}

Initiera Terraform

Kör terraform init för att initiera Terraform-distributionen. Det här kommandot laddar ned den Azure-provider som krävs för att hantera dina Azure-resurser.

terraform init -upgrade

Viktiga punkter:

  • Parametern -upgrade uppgraderar nödvändiga provider-plugin-program till den senaste versionen som uppfyller konfigurationens versionsbegränsningar.

Skapa en Terraform-utförandeplan

Kör terraform plan för att skapa en körplan.

terraform plan -out main.tfplan

Viktiga punkter:

  • Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
  • Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

Tillämpa en Terraform-utförandeplan

Kör terraform apply för att tillämpa körningsplanen på din molninfrastruktur.

terraform apply main.tfplan

Viktiga punkter:

  • terraform apply Exempelkommandot förutsätter att du tidigare körde terraform plan -out main.tfplan.
  • Om du har angett ett annat filnamn för parametern -out använder du samma filnamn i anropet till terraform apply.
  • Om du inte använde parametern -out anropar du terraform apply utan några parametrar.

Verifiera resultatet

Kör az eventhubs namespace network-rule-set show för att visa nätverksreglerna för Event Hubs-namnrymden.

az eventhubs namespace network-rule show --resource-group <resource_group_name> --namespace-name <namespace_name>

Viktiga punkter:

  • Resursgruppens namn och Namnområdesnamn för Event Hubs visas i terraform apply utdata.

Rensa resurser

Gör följande när du inte längre behöver de resurser som skapats via Terraform:

  1. Kör terraform plan och ange destroy flagga.

    terraform plan -destroy -out main.destroy.tfplan

    Viktiga punkter:

    • Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
    • Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

  2. Utför terraform apply för att tillämpa exekveringsplanen.

    terraform apply main.destroy.tfplan

Felsöka Terraform i Azure

Felsöka vanliga problem när du använder Terraform i Azure

Nästa steg

Läs mer om hur du använder Terraform i Azure