Snabbstart: Skapa en Azure SQL Database-server och databas med Terraform

Gäller för:Azure SQL Database

Att skapa en enkel databas är det snabbaste och enklaste alternativet för att skapa en databas i Azure SQL Database. Den här snabbstarten visar hur du skapar en enkel databas med Terraform.

Terraform möjliggör definition, förhandsversion och distribution av molninfrastruktur. Med Terraform skapar du konfigurationsfiler med hjälp av HCL-syntax. Med HCL-syntaxen kan du ange molnleverantören – till exempel Azure – och de element som utgör din molninfrastruktur. När du har skapat konfigurationsfilerna skapar du en körningsplan som gör att du kan förhandsgranska ändringarna i infrastrukturen innan de distribueras. När du har verifierat ändringarna tillämpar du genomförandeplanen för att implementera infrastrukturen.

I den här artikeln lär du dig att:

Förutsättningar

• Installera och konfigurera Terraform

Behörigheter

För att skapa databaser via Transact-SQL: CREATE DATABASE behörigheter är nödvändiga. Om du vill skapa en databas måste en inloggning vara antingen serveradministratörens inloggning (som skapades när den logiska Azure SQL Database-servern etablerades), Microsoft Entra-administratören för servern, eller en medlem av dbmanager-databasrollen i master. Mer information finns i SKAPA DATABAS.

För att skapa databaser via Azure-portalen, PowerShell, Azure CLI eller REST API: Azure RBAC-behörigheter krävs, särskilt rollen Deltagare, SQL DB-deltagare eller SQL Server-deltagare i Azure RBAC. Mer information finns i Inbyggda Azure RBAC-roller.

Utför implementeringen av Terraform-koden

1. Skapa en katalog där du kan testa och köra Terraform-exempelkoden och göra den till den aktuella katalogen.

2. Skapa en fil med namnet providers.tf och infoga följande kod:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

3. Skapa en fil med namnet main.tf och infoga följande kod:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_pet" "azurerm_mssql_server_name" {
     prefix = "sql"
   }
   
   resource "random_password" "admin_password" {
     count       = var.admin_password == null ? 1 : 0
     length      = 20
     special     = true
     min_numeric = 1
     min_upper   = 1
     min_lower   = 1
     min_special = 1
   }
   
   locals {
     admin_password = try(random_password.admin_password[0].result, var.admin_password)
   }
   
   resource "azurerm_mssql_server" "server" {
     name                         = random_pet.azurerm_mssql_server_name.id
     resource_group_name          = azurerm_resource_group.rg.name
     location                     = azurerm_resource_group.rg.location
     administrator_login          = var.admin_username
     administrator_login_password = local.admin_password
     version                      = "12.0"
   }
   
   resource "azurerm_mssql_database" "db" {
     name      = var.sql_db_name
     server_id = azurerm_mssql_server.server.id
   }
   

4. Skapa en fil med namnet variables.tf och infoga följande kod:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sql_db_name" {
     type        = string
     description = "The name of the SQL Database."
     default     = "SampleDB"
   }
   
   variable "admin_username" {
     type        = string
     description = "The administrator username of the SQL logical server."
     default     = "azureadmin"
   }
   
   variable "admin_password" {
     type        = string
     description = "The administrator password of the SQL logical server."
     sensitive   = true
     default     = null
   }
   

5. Skapa en fil med namnet outputs.tf och infoga följande kod:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "sql_server_name" {
     value = azurerm_mssql_server.server.name
   }
   
   
   output "admin_password" {
     sensitive = true
     value     = local.admin_password
   }
   

Initiera Terraform

Kör terraform init för att initiera Terraform-distributionen. Det här kommandot laddar ned den Azure-provider som krävs för att hantera dina Azure-resurser.

terraform init -upgrade

Viktiga punkter:

• Parametern -upgrade uppgraderar nödvändiga provider-plugin-program till den senaste versionen som uppfyller konfigurationens versionsbegränsningar.

Skapa en Terraform-utförandeplan

Kör terraform plan för att skapa en exekveringsplan.

terraform plan -out main.tfplan

Viktiga punkter:

• Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
• Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

Tillämpa en Terraform-utförandeplan

Kör terraform apply för att tillämpa utförandeplanen på din molninfrastruktur.

terraform apply main.tfplan

Viktiga punkter:

• terraform apply Exempelkommandot förutsätter att du tidigare körde terraform plan -out main.tfplan.
• Om du har angett ett annat filnamn för parametern -out använder du samma filnamn i anropet till terraform apply.
• Om du inte använde parametern -out anropar du terraform apply utan några parametrar.

Verifiera resultatet

Rensa resurser

Gör följande när du inte längre behöver de resurser som skapats via Terraform:

1. Kör terraform plan och specificera destroy flaggan.

   terraform plan -destroy -out main.destroy.tfplan
   

   Viktiga punkter:

   • Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
   • Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

2. Kör terraform apply för att genomföra exekveringsplanen.

   terraform apply main.destroy.tfplan
   

Felsöka Terraform i Azure

Felsöka vanliga problem när du använder Terraform i Azure

Nästa steg