Strängfunktioner för Bicep

Den här artikeln beskriver Bicep-funktionerna för att arbeta med strängar.

base64

base64(inputString)

Returnerar base64-representationen av indatasträngen.

Namnområde: sys.

Parametrar

Returvärde

En sträng som innehåller base64-representationen.

Exempel

I följande exempel visas hur du använder funktionen base64.

param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'

var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)

output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)

Utdata från föregående exempel med standardvärdena är:

base64ToJson

base64ToJson(base64Value)

Konverterar en base64-representation till ett JSON-objekt.

Namnområde: sys.

Parametrar

Returvärde

Ett JSON-objekt.

Exempel

I följande exempel används funktionen base64ToJson för att konvertera ett base64-värde:

param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'

var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)

output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)

Utdata från föregående exempel med standardvärdena är:

base64ToString

base64ToString(base64Value)

Konverterar en base64-representation till en sträng.

Namnområde: sys.

Parametrar

Returvärde

En sträng med det konverterade base64-värdet.

Exempel

I följande exempel används funktionen base64ToString för att konvertera ett base64-värde:

param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'

var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)

output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)

Utdata från föregående exempel med standardvärdena är:

buildUri

buildUri(uriComponent)

Konstruerar en URI genom att kombinera det angivna schemat, värden, porten, sökvägen och frågekomponentobjektet till en enda URI-sträng. Information om hur du parsar en URI finns i parseUri.

Namnområde: sys.

Parametrar

Returvärde

En sträng som representerar den absoluta URI som skapats från de tillhandahållna komponenterna.

Exempel

I följande exempel visas hur du använder buildUri för att konstruera en URI från enskilda komponenter:

param uriComponents object = {
  scheme: 'https'
  host: 'mystorage.blob.core.windows.net'
  port: 8080
  path: '/templates/nestedTemplate.json'
  query: '?st=2025-05-09'
}

output constructedUri string = buildUri((uriComponents))

Utdata från föregående exempel är:

I följande exempel visas hur du använder parseUri för att extrahera komponenter från en befintlig URI, ändra dem och sedan använda buildUri för att rekonstruera en ny URI:

param uriComponents object = parseUri('https://mystorage.blob.core.windows.net:8080/templates/nestedTemplate.json?st=2025-05-09')
param newQuery string = 'st-2025-06-19'

var updatedUriComponents object = { 
  scheme: uriComponents.schema
  host: uriComponents.host
  port: uriComponents.port
  path: uriComponents.path
  query: newQuery
}

// Reconstruct the URI using buildUri
output reconstructedUri string = buildUri(updatedUriComponents)

Utdata från föregående exempel är:

concat

concat(arg1, arg2, arg3, ...)

Kombinerar flera strängvärden och returnerar den sammanfogade strängen, eller kombinerar flera matriser och returnerar den sammanfogade matrisen. Använd stränginterpolation i stället för funktionen för att förbättra läsbarheten.concat() Men i vissa fall, till exempel strängersättning i flerradssträngar, kan du behöva återgå till att använda concat() funktionen eller replace() funktionen.

Namnområde: sys.

Parametrar

Den här funktionen kan ta valfritt antal argument och kan acceptera antingen strängar eller matriser för parametrarna. Du kan dock inte ange både matriser och strängar för parametrar. Strängar sammanfogas bara med andra strängar.

Returvärde

En sträng eller matris med sammanfogade värden.

Exempel

I följande exempel visas en jämförelse mellan att använda interpolering och att använda concat() funktionen. De två utdata returnerar samma värde.

param prefix string = 'prefix'

output concatOutput string = concat(prefix, 'And', uniqueString(resourceGroup().id))
output interpolationOutput string = '${prefix}And${uniqueString(resourceGroup().id)}'

Utdata från föregående exempel med standardvärdet är:

Interpolering stöds för närvarande inte i flerradssträngar. I följande exempel visas en jämförelse mellan att använda interpolering och att använda concat() funktionen.

var blocked = 'BLOCKED'

output concatOutput string = concat('''interpolation
is ''', blocked)
output interpolationOutput string = '''interpolation
is ${blocked}'''

Utdata från föregående exempel med standardvärdena är:

innehåller

contains(container, itemToFind)

Kontrollerar om en matris innehåller ett värde, ett objekt innehåller en nyckel eller om en sträng innehåller en delsträng. Strängjämförelsen är skiftlägeskänslig. Men när du testar om ett objekt innehåller en nyckel är jämförelsen skiftlägeskänslig.

Namnområde: sys.

Parametrar

Returvärde

Trueom objektet hittas; annars . False

Exempel

I följande exempel visas hur du använder containrar med olika typer:

param stringToTest string = 'OneTwoThree'
param objectToTest object = {
  one: 'a'
  two: 'b'
  three: 'c'
}
param arrayToTest array = [
  'one'
  'two'
  'three'
]

output stringTrue bool = contains(stringToTest, 'e')
output stringFalse bool = contains(stringToTest, 'z')
output objectTrue bool = contains(objectToTest, 'one')
output objectFalse bool = contains(objectToTest, 'a')
output arrayTrue bool = contains(arrayToTest, 'three')
output arrayFalse bool = contains(arrayToTest, 'four')

Utdata från föregående exempel med standardvärdena är:

dataUri

dataUri(stringToConvert)

Konverterar ett värde till en data-URI.

Namnområde: sys.

Parametrar

Returvärde

En sträng formaterad som en data-URI.

Exempel

I följande exempel konverteras ett värde till en data-URI och en data-URI konverteras till en sträng:

param stringToTest string = 'Hello'
param dataFormattedString string = 'data:;base64,SGVsbG8sIFdvcmxkIQ=='

output dataUriOutput string = dataUri(stringToTest)
output toStringOutput string = dataUriToString(dataFormattedString)

Utdata från föregående exempel med standardvärdena är:

dataUriToString

dataUriToString(dataUriToConvert)

Konverterar ett data-URI-formaterat värde till en sträng.

Namnområde: sys.

Parametrar

Returvärde

En sträng som innehåller det konverterade värdet.

Exempel

I följande exempel konverteras ett värde till en data-URI och en data-URI konverteras till en sträng:

param stringToTest string = 'Hello'
param dataFormattedString string = 'data:;base64,SGVsbG8sIFdvcmxkIQ=='

output dataUriOutput string = dataUri(stringToTest)
output toStringOutput string = dataUriToString(dataFormattedString)

Utdata från föregående exempel med standardvärdena är:

tom

empty(itemToTest)

Avgör om en matris, ett objekt eller en sträng är tom eller null.

Namnområde: sys.

Parametrar

Returvärde

Returnerar Sant om värdet är tomt eller null. Annars falskt.

Exempel

I följande exempel kontrolleras om en matris, ett objekt och en sträng är tomma.

param testArray array = []
param testObject object = {}
param testString string = ''
param testNullString string?

output arrayEmpty bool = empty(testArray)
output objectEmpty bool = empty(testObject)
output stringEmpty bool = empty(testString)
output stringNull bool = empty(testNullString)

Utdata från föregående exempel med standardvärdena är:

slutar med

endsWith(stringToSearch, stringToFind)

Avgör om en sträng slutar med ett värde. Jämförelsen är skiftlägeskänslig.

Namnområde: sys.

Parametrar

Returvärde

Trueom strängens sista tecken eller tecken matchar värdet. annars . False

Exempel

I följande exempel visas hur du använder funktionerna startsWith och endsWith:

output startsTrue bool = startsWith('abcdef', 'ab')
output startsCapTrue bool = startsWith('abcdef', 'A')
output startsFalse bool = startsWith('abcdef', 'e')
output endsTrue bool = endsWith('abcdef', 'ef')
output endsCapTrue bool = endsWith('abcdef', 'F')
output endsFalse bool = endsWith('abcdef', 'e')

Utdata från föregående exempel med standardvärdena är:

Första

first(arg1)

Returnerar det första tecknet i strängen eller det första elementet i matrisen. Om en tom sträng anges resulterar funktionen i en tom sträng. När det gäller en tom matris returnerar nullfunktionen .

Namnområde: sys.

Parametrar

Returvärde

En sträng med det första tecknet, eller typen (sträng, int, matris eller objekt) för det första elementet i en matris.

Exempel

I följande exempel visas hur du använder den första funktionen med en matris och sträng.

param arrayToTest array = [
  'one'
  'two'
  'three'
]

output arrayOutput string = first(arrayToTest)
output stringOutput string = first('One Two Three')

Utdata från föregående exempel med standardvärdena är:

format

format(formatString, arg1, arg2, ...)

Skapar en formaterad sträng från indatavärden.

Namnområde: sys.

Parametrar

Kommentarer

Använd den här funktionen för att formatera en sträng i Bicep-filen. Den använder samma formateringsalternativ som metoden System.String.Format i .NET.

Exempel

I följande exempel visas hur du använder formatfunktionen.

param greeting string = 'Hello'
param name string = 'User'
param numberToFormat int = 8175133
param objectToFormat object = { prop: 'value' }

output formatTest string = format('{0}, {1}. Formatted number: {2:N0}', greeting, name, numberToFormat)
output formatObject string = format('objectToFormat: {0}', objectToFormat)

Utdata från föregående exempel med standardvärdena är:

riktlinje

guid(baseString, ...)

Skapar ett värde i formatet för en globalt unik identifierare baserat på de värden som anges som parametrar.

Namnområde: sys.

Parametrar

Kommentarer

Den här funktionen är användbar när du behöver skapa ett värde i formatet för en globalt unik identifierare. Du anger parametervärden som begränsar omfattningen av unikhet för resultatet. Du kan ange om namnet är unikt ned till prenumeration, resursgrupp eller distribution.

Det returnerade värdet är inte en slumpmässig sträng, utan snarare resultatet av en hash-funktion på parametrarna. Det returnerade värdet är 36 tecken långt. Det är inte globalt unikt. Om du vill skapa ett nytt GUID som inte baseras på det hashvärdet för parametrarna använder du funktionen newGuid .

I följande exempel visas hur du använder guid för att skapa ett unikt värde för vanliga nivåer.

Unikt omfång för prenumeration

guid(subscription().subscriptionId)

Unikt omfång för resursgrupp

guid(resourceGroup().id)

Unikt omfång för distribution för en resursgrupp

guid(resourceGroup().id, deployment().name)

Funktionen guid implementerar algoritmen från RFC 4122 §4.3. Den ursprungliga källan finns i GuidUtility med vissa ändringar. I funktionsimplementeringen är inställt på guid(), och namespaceId är inställt på 11fb06fb-712d-4ddd-98c7-e71bbd588830.version5 Värdet genereras genom att konvertera varje parameter i guid() funktionen till en sträng och sammanfoga dem med - som avgränsare.

Returvärde

En sträng som innehåller 36 tecken i formatet för en globalt unik identifierare.

Exempel

I följande exempel returneras resultat från guid:

output guidPerSubscription string = guid(subscription().subscriptionId)
output guidPerResourceGroup string = guid(resourceGroup().id)
output guidPerDeployment string = guid(resourceGroup().id, deployment().name)

indexOf

indexOf(stringToSearch, stringToFind)

Returnerar den första positionen för ett värde i en sträng. Jämförelsen är skiftlägeskänslig.

Namnområde: sys.

Parametrar

Returvärde

Ett heltal som representerar positionen för objektet som ska hittas. Värdet är nollbaserat. Om objektet inte hittas returneras -1.

Exempel

I följande exempel visas hur du använder funktionerna indexOf och lastIndexOf:

output firstT int = indexOf('test', 't')
output lastT int = lastIndexOf('test', 't')
output firstString int = indexOf('abcdef', 'CD')
output lastString int = lastIndexOf('abcdef', 'AB')
output notFound int = indexOf('abcdef', 'z')

Utdata från föregående exempel med standardvärdena är:

anslut

join(inputArray, delimiter)

Kopplar en strängmatris till en enskild sträng, avgränsad med en avgränsare.

Namnområde: sys.

Parametrar

Returvärde

En sträng.

Exempel

I följande exempel kopplas indatasträngmatrisen till strängar som avgränsas med antingen ett kommatecken eller ett semikolon.

var arrayString = [
  'one'
  'two'
  'three'
]

output firstOutput string = join(arrayString, ',')
output secondOutput string = join(arrayString, ';')

Utdata från föregående exempel med standardvärdena är:

Den här funktionen kräver Bicep CLI version 0.8.X eller senare.

json

json(arg1)

Konverterar en giltig JSON-sträng till en JSON-datatyp. Mer information finns i json-funktionen.

Namnområde: sys.

senaste

last(arg1)

Returnerar strängens sista tecken eller det sista elementet i matrisen.

Namnområde: sys.

Parametrar

Returvärde

En sträng med det sista tecknet, eller typen (sträng, int, matris eller objekt) för det sista elementet i en matris.

Exempel

I följande exempel visas hur du använder den sista funktionen med en matris och sträng.

param arrayToTest array = [
  'one'
  'two'
  'three'
]

output arrayOutput string = last(arrayToTest)
output stringOutput string = last('One Two Three')

Utdata från föregående exempel med standardvärdena är:

lastIndexOf

lastIndexOf(stringToSearch, stringToFind)

Returnerar den sista positionen för ett värde i en sträng. Jämförelsen är skiftlägeskänslig.

Namnområde: sys.

Parametrar

Returvärde

Ett heltal som representerar objektets sista position att hitta. Värdet är nollbaserat. Om objektet inte hittas returneras -1.

Exempel

I följande exempel visas hur du använder indexOf funktionerna och lastIndexOf :

output firstT int = indexOf('test', 't')
output lastT int = lastIndexOf('test', 't')
output firstString int = indexOf('abcdef', 'CD')
output lastString int = lastIndexOf('abcdef', 'AB')
output notFound int = indexOf('abcdef', 'z')

Utdata från föregående exempel med standardvärdena är:

längd

length(string)

Returnerar antalet tecken i en sträng, element i en matris eller egenskaper på rotnivå i ett objekt.

Namnområde: sys.

Parametrar

Returvärde

Ett int.

Exempel

I följande exempel visas hur du använder längd med en matris och sträng:

param arrayToTest array = [
  'one'
  'two'
  'three'
]
param stringToTest string = 'One Two Three'
param objectToTest object = {
  propA: 'one'
  propB: 'two'
  propC: 'three'
  propD: {
    'propD-1': 'sub'
    'propD-2': 'sub'
  }
}

output arrayLength int = length(arrayToTest)
output stringLength int = length(stringToTest)
output objectLength int = length(objectToTest)

Utdata från föregående exempel med standardvärdena är:

nyGuid

newGuid()

Returnerar ett värde i formatet för en globalt unik identifierare. Den här funktionen kan bara användas i standardvärdet för en parameter.

Namnområde: sys.

Kommentarer

Du kan bara använda den här funktionen i ett uttryck för standardvärdet för en parameter. Om du använder den här funktionen någon annanstans i en Bicep-fil returneras ett fel. Funktionen tillåts inte i andra delar av Bicep-filen eftersom den returnerar ett annat värde varje gång den anropas. Att distribuera samma Bicep-fil med samma parametrar skulle inte ge samma resultat på ett tillförlitligt sätt.

Funktionen newGuid skiljer sig från guid-funktionen eftersom den inte tar några parametrar. När du anropar guid med samma parametrar returneras samma identifierare varje gång. Använd guid när du behöver generera samma GUID på ett tillförlitligt sätt för en specifik miljö. Använd newGuid när du behöver en annan identifierare varje gång, till exempel distribuera resurser till en testmiljö.

Funktionen newGuid använder Guid-strukturen i .NET Framework för att generera den globalt unika identifieraren.

Om du använder alternativet för att distribuera om en tidigare lyckad distribution, och den tidigare distributionen innehåller en parameter som använder newGuid, utvärderas inte parametern igen. I stället återanvänds parametervärdet från den tidigare distributionen automatiskt i återställningsdistributionen.

I en testmiljö kan du behöva distribuera resurser som bara finns under en kort tid upprepade gånger. I stället för att skapa unika namn kan du använda newGuid med uniqueString för att skapa unika namn.

Var försiktig med att distribuera om en Bicep-fil som förlitar sig på funktionen newGuid för ett standardvärde. När du distribuerar om och inte anger något värde för parametern utvärderas funktionen igen. Om du vill uppdatera en befintlig resurs i stället för att skapa en ny skickar du parametervärdet från den tidigare distributionen.

Returvärde

En sträng som innehåller 36 tecken i formatet för en globalt unik identifierare.

Exempel

I följande exempel visas en parameter med en ny identifierare.

param guidValue string = newGuid()

output guidOutput string = guidValue

Utdata från föregående exempel varierar för varje distribution men kommer att likna:

I följande exempel används funktionen newGuid för att skapa ett unikt namn för ett lagringskonto. Den här Bicep-filen kan fungera för testmiljön där lagringskontot finns under en kort tid och inte distribueras om.

param guidValue string = newGuid()

var storageName = 'storage${uniqueString(guidValue)}'

resource myStorage 'Microsoft.Storage/storageAccounts@2023-04-01' = {
  name: storageName
  location: 'West US'
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
  properties: {}
}

output nameOutput string = storageName

Utdata från föregående exempel varierar för varje distribution men kommer att likna:

padLeft

padLeft(valueToPad, totalLength, paddingCharacter)

Returnerar en högerjusterad sträng genom att lägga till tecken till vänster tills den totala angivna längden har nåtts.

Namnområde: sys.

Parametrar

Om den ursprungliga strängen är längre än antalet tecken som ska fyllas i läggs inga tecken till.

Returvärde

En sträng med minst antalet angivna tecken.

Exempel

I följande exempel visas hur du fyller på parametervärdet som tillhandahålls av användaren genom att lägga till nolltecknet tills det totala antalet tecken når det totala antalet tecken.

param testString string = '123'

output stringOutput string = padLeft(testString, 10, '0')

Utdata från föregående exempel med standardvärdena är:

parseUri

parseUri(uriString)

Parsar en URI-sträng i dess komponenter, till exempel schema, värd, port, sökväg och fråga. Information om hur du skapar en URI-sträng finns i buildUri.

Namnområde: sys.

Parametrar

Returvärde

Ett objekt som innehåller de parsade URI-komponenterna med följande egenskaper:

För fullständig information tolkas URI:n enligt beskrivningen i RFC 3986, avsnitt 3.

Exempel

I följande exempel visas hur du använder parseUri för att extrahera komponenter från en URI:

param inputUri string = 'https://mystorage.blob.core.windows.net:8080/templates/nestedTemplate.json?st=2025-05-09'

var parsedUri = parseUri(inputUri)

output scheme string = parsedUri.scheme
output host string = parsedUri.host
output port int = parsedUri.port
output path string = parsedUri.path
output query string = parsedUri.query

Utdata från föregående exempel med standardvärdena är:

I följande exempel visas hur du använder parseUri för att extrahera värden och schemat och sedan rekonstruera en ny URI med en annan sökväg med hjälp av uri funktionen:

param originalUri string = 'https://mystorage.blob.core.windows.net/data/file.json?st=2025-05-09'

var parsedUri = parseUri(originalUri)
var newPath = '/newdata/newfile.json'
var modifiedUri = uri('${parsedUri.scheme}://${parsedUri.host}', newPath)

output originalHost string = parsedUri.host
output newUri string = modifiedUri

Utdata från föregående exempel är:

ersätt

replace(originalString, oldString, newString)

Returnerar en ny sträng med alla instanser av en sträng ersatt av en annan sträng.

Namnområde: sys.

Parametrar

Returvärde

En sträng med de ersatta tecknen.

Exempel

I följande exempel visas hur du tar bort alla bindestreck från den användardefinierade strängen och hur du ersätter en del av strängen med en annan sträng.

param testString string = '123-123-1234'

output firstOutput string = replace(testString, '-', '')
output secondOutput string = replace(testString, '1234', 'xxxx')

Utdata från föregående exempel med standardvärdena är:

hoppa över

skip(originalValue, numberToSkip)

Returnerar en sträng med alla tecken efter det angivna antalet tecken eller en matris med alla element efter det angivna antalet element.

Namnområde: sys.

Parametrar

Returvärde

En matris eller sträng.

Exempel

I följande exempel hoppar över det angivna antalet element i matrisen och det angivna antalet tecken i en sträng.

param testArray array = [
  'one'
  'two'
  'three'
]
param elementsToSkip int = 2
param testString string = 'one two three'
param charactersToSkip int = 4

output arrayOutput array = skip(testArray, elementsToSkip)
output stringOutput string = skip(testString, charactersToSkip)

Utdata från föregående exempel med standardvärdena är:

dela

split(inputString, delimiter)

Returnerar en matris med strängar som innehåller delsträngarna för indatasträngen som avgränsas av de angivna avgränsarna.

Namnområde: sys.

Parametrar

Returvärde

En matris med strängar.

Exempel

I följande exempel delas indatasträngen med ett kommatecken och med antingen ett kommatecken eller ett semikolon.

param firstString string = 'one,two,three'
param secondString string = 'one;two,three'

var delimiters = [
  ','
  ';'
]

output firstOutput array = split(firstString, ',')
output secondOutput array = split(secondString, delimiters)

Utdata från föregående exempel med standardvärdena är:

börjar med

startsWith(stringToSearch, stringToFind)

Avgör om en sträng börjar med ett värde. Jämförelsen är skiftlägeskänslig.

Namnområde: sys.

Parametrar

Returvärde

Trueom det första tecknet eller tecknen i strängen matchar värdet; annars . False

Exempel

I följande exempel visas hur du använder funktionerna startsWith och endsWith:

output startsTrue bool = startsWith('abcdef', 'ab')
output startsCapTrue bool = startsWith('abcdef', 'A')
output startsFalse bool = startsWith('abcdef', 'e')
output endsTrue bool = endsWith('abcdef', 'ef')
output endsCapTrue bool = endsWith('abcdef', 'F')
output endsFalse bool = endsWith('abcdef', 'e')

Utdata från föregående exempel med standardvärdena är:

sträng

string(valueToConvert)

Konverterar det angivna värdet till en sträng. Strängar returneras som de är. Andra typer konverteras till motsvarande JSON-representation. Om du behöver konvertera en sträng till JSON, d.v.s. quote/escape it, kan du använda substring(string([value]), 1, length(string([value]) - 2).

Namnområde: sys.

Parametrar

Returvärde

En sträng med det konverterade värdet.

Exempel

I följande exempel visas hur du konverterar olika typer av värden till strängar:

param testObject object = {
  valueA: 10
  valueB: 'Example Text'
}
param testArray array = [
  '\'a\''
  '"b"'
  '\\c\\'
]
param testInt int = 5
param testString string = 'foo " \' \\'

output objectOutput string = string(testObject)
output arrayOutput string = string(testArray)
output intOutput string = string(testInt)
output stringOutput string = string(testString)
output stringEscapedOutput string = substring(string([testString]), 1, length(string([testString])) - 2)

Utdata från föregående exempel med standardvärdena är:

Delsträng

substring(stringToParse, startIndex, length)

Returnerar en delsträng som börjar vid den angivna teckenpositionen och innehåller det angivna antalet tecken.

Namnområde: sys.

Parametrar

Returvärde

Delsträngen. Eller en tom sträng om längden är noll.

Kommentarer

Funktionen misslyckas när delsträngen sträcker sig bortom slutet av strängen eller när längden är mindre än noll. Följande exempel misslyckas med felet "Index- och längdparametrarna måste referera till en plats i strängen. Indexparametern: '0', längdparametern: '11', längden på strängparametern: '10'.".

param inputString string = '1234567890'

var prefix = substring(inputString, 0, 11)

Exempel

I följande exempel extraheras en delsträng från en parameter.

param testString string = 'one two three'
output substringOutput string = substring(testString, 4, 3)

Utdata från föregående exempel med standardvärdena är:

ta

take(originalValue, numberToTake)

Returnerar en sträng med det angivna antalet tecken från början av strängen, eller en matris med det angivna antalet element från början av matrisen.

Namnområde: sys.

Parametrar

Returvärde

En matris eller sträng.

Exempel

I följande exempel används det angivna antalet element från matrisen och tecken från en sträng.

param testArray array = [
  'one'
  'two'
  'three'
]
param elementsToTake int = 2
param testString string = 'one two three'
param charactersToTake int = 2

output arrayOutput array = take(testArray, elementsToTake)
output stringOutput string = take(testString, charactersToTake)

Utdata från föregående exempel med standardvärdena är:

toLower

toLower(stringToChange)

Konverterar den angivna strängen till gemener.

Namnområde: sys.

Parametrar

Returvärde

Strängen konverterades till gemener.

Exempel

I följande exempel konverteras ett parametervärde till gemener och versaler.

param testString string = 'One Two Three'

output toLowerOutput string = toLower(testString)
output toUpperOutput string = toUpper(testString)

Utdata från föregående exempel med standardvärdena är:

toUpper

toUpper(stringToChange)

Konverterar den angivna strängen till versaler.

Namnområde: sys.

Parametrar

Returvärde

Strängen konverterades till versaler.

Exempel

I följande exempel konverteras ett parametervärde till gemener och versaler.

param testString string = 'One Two Three'

output toLowerOutput string = toLower(testString)
output toUpperOutput string = toUpper(testString)

Utdata från föregående exempel med standardvärdena är:

trimma

trim(stringToTrim)

Tar bort alla inledande och avslutande blankstegstecken från den angivna strängen.

Namnområde: sys.

Parametrar

Returvärde

Strängen utan inledande och avslutande blankstegstecken.

Exempel

I följande exempel trimmas blankstegstecken från parametern.

param testString string = '    one two three   '

output return string = trim(testString)

Utdata från föregående exempel med standardvärdena är:

uniqueString

uniqueString(baseString, ...)

Skapar en deterministisk hashsträng baserat på de värden som anges som parametrar.

Namnområde: sys.

Parametrar

Kommentarer

Den här funktionen är användbar när du behöver skapa ett unikt namn för en resurs. Du anger parametervärden som begränsar omfattningen av unikhet för resultatet. Du kan ange om namnet är unikt ned till prenumeration, resursgrupp eller distribution.

Det returnerade värdet är inte en slumpmässig sträng, utan snarare resultatet av en hash-funktion. Det returnerade värdet är 13 tecken långt. Det är inte globalt unikt. Du kanske vill kombinera värdet med ett prefix från namngivningskonventionen för att skapa ett namn som är meningsfullt. I följande exempel visas formatet för det returnerade värdet. Det faktiska värdet varierar beroende på de angivna parametrarna.

tcvhiyu5h2o5o

I följande exempel visas hur du använder uniqueString för att skapa ett unikt värde för vanliga nivåer.

Unikt omfång för prenumeration

uniqueString(subscription().subscriptionId)

Unikt omfång för resursgrupp

uniqueString(resourceGroup().id)

Unikt omfång för distribution för en resursgrupp

uniqueString(resourceGroup().id, deployment().name)

I följande exempel visas hur du skapar ett unikt namn för ett lagringskonto baserat på din resursgrupp. I resursgruppen är namnet inte unikt om det konstrueras på samma sätt.

resource mystorage 'Microsoft.Storage/storageAccounts@2023-04-01' = {
  name: 'storage${uniqueString(resourceGroup().id)}'
  ...
}

Om du behöver skapa ett nytt unikt namn varje gång du distribuerar en Bicep-fil och inte tänker uppdatera resursen kan du använda funktionen utcNow med uniqueString. Du kan använda den här metoden i en testmiljö. Ett exempel finns i utcNow. Observera att funktionen utcNow bara kan användas i ett uttryck för standardvärdet för en parameter.

Returvärde

En sträng som innehåller 13 tecken.

Exempel

I följande exempel returneras resultat från uniquestring:

output uniqueRG string = uniqueString(resourceGroup().id)
output uniqueDeploy string = uniqueString(resourceGroup().id, deployment().name)

URI

uri(baseUri, relativeUri)

Skapar en absolut URI genom att kombinera baseUri och relativeUri-strängen.

Namnområde: sys.

Parametrar

• Om baseUri slutar med ett avslutande snedstreck följs resultatet helt enkelt baseUri av relativeUri. Om relativeUri det också börjar med ett inledande snedstreck kombineras det avslutande snedstrecket och det inledande snedstrecket till ett.

• Om baseUri inte slutar i ett avslutande snedstreck händer en av två saker.

  • Om baseUri det inte finns några snedstreck alls (förutom "//" nära framsidan) följs resultatet helt enkelt baseUri av relativeUri.

  • Om baseUri har vissa snedstreck, men inte slutar med ett snedstreck, tas allt från det senaste snedstrecket och framåt bort och baseUri resultatet baseUri följs av relativeUri.

Nedan följer några exempel:

uri('http://contoso.org/firstpath', 'myscript.sh') -> http://contoso.org/myscript.sh
uri('http://contoso.org/firstpath/', 'myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/', '/myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/azuredeploy.json', 'myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/azuredeploy.json/', 'myscript.sh') -> http://contoso.org/firstpath/azuredeploy.json/myscript.sh

För fullständig information matchas parametrarna och baseUri enligt beskrivningen relativeUri i RFC 3986, avsnitt 5.

Returvärde

En sträng som representerar den absoluta URI:n för bas- och relativa värden.

Exempel

I följande exempel visas hur du använder uri, uriComponent och uriComponentToString:

var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)

output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)

Utdata från föregående exempel med standardvärdena är:

URI-komponent

uricomponent(stringToEncode)

Kodar en URI.

Namnområde: sys.

Parametrar

Returvärde

En sträng med det URI-kodade värdet.

Exempel

I följande exempel visas hur du använder uri, uriComponent och uriComponentToString:

var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)

output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)

Utdata från föregående exempel med standardvärdena är:

uriComponentToString

uriComponentToString(uriEncodedString)

Returnerar en sträng med ett URI-kodat värde.

Namnområde: sys.

Parametrar

Returvärde

En avkodad sträng med URI-kodat värde.

Exempel

I följande exempel visas hur du använder uri, uriComponent och uriComponentToString:

var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)

output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)

Utdata från föregående exempel med standardvärdena är:

Nästa steg

• En beskrivning av avsnitten i en Bicep-fil finns i Förstå strukturen och syntaxen för Bicep-filer.
• Information om hur du itererar ett angivet antal gånger när du skapar en typ av resurs finns i Iterativa loopar i Bicep.
• Information om hur du distribuerar den Bicep-fil som du har skapat finns i Distribuera resurser med Bicep och Azure PowerShell.