Frågor för LAQueryLogs-tabellen

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Mest efterfrågade resurs-id

De flesta efterfrågade resurser under de senaste 24 timmarna.

LAQueryLogs
| extend reqContext = parse_json(RequestContext)
| extend datasources = array_concat(reqContext["resources"], reqContext["workspaces"], reqContext["applications"])
| mv-expand datasources
| summarize reqCount = count() by tostring(datasources)
| order by reqCount desc

Obehöriga användare

Hämta en lista över obehöriga användare med antalet förfrågningar under de senaste 24 timmarna.

LAQueryLogs
| where ResponseCode == "403"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

Begränsade användare

Hämta en lista över begränsade användare med antalet förfrågningar under de senaste 24 timmarna.

LAQueryLogs
| where ResponseCode == "429"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

Antal begäranden efter ResponseCode

Antal begäranden efter svarskod inom 1 min buckets under de senaste 1 timmen.

LAQueryLogs
| where TimeGenerated > ago(1h)
| summarize count() by tostring(ResponseCode), bin(TimeGenerated, 1m)
| render columnchart with (kind=stacked)

De 10 mest resursintensiva frågorna

Hämta de tio mest resurskrävande frågorna (baserat på CPU-användning) under de senaste 24 timmarna.

LAQueryLogs
| top 10 by StatsCPUTimeMs desc nulls last 

Frågor om de 10 längsta tidsintervallen

Få de 10 vanligaste frågorna som genomsökt det längsta tidsintervallet under de senaste 24 timmarna.

LAQueryLogs
| extend DataProcessedTimeRange = format_timespan(StatsDataProcessedEnd - StatsDataProcessedStart, 'dd.hh:mm:ss:FF')
| top 10 by DataProcessedTimeRange desc nulls last