Frågor för KubePodInventory-tabellen

För information om hur du använder dessa frågor i Azure-portalen, se Log Analytics-handledningen. Information om REST-API:et finns i Fråga.

Pods i kraschloop

Avgör om Pods/Containers befinner sig i en crash-loop-fas.

//Determines whether Pods/Containers has Crash-Loop phase
KubePodInventory
| where ContainerStatus  == 'waiting' 
| where ContainerStatusReason == 'CrashLoopBackOff' or ContainerStatusReason == 'Error'
| extend ContainerLastStatus=todynamic(ContainerLastStatus)
| summarize RestartCount = arg_max(ContainerRestartCount, Computer, Namespace, ContainerLastStatus.reason) by Name

Pods i vänteläge

Kontrollera Pods som inte kan startas och deras väntetid.

//Check Pods that cannot be started and its pending time
KubePodInventory
| where PodStatus == 'Pending'
| project PodCreationTimeStamp, Namespace, PodStartTime, PodStatus, Name, ContainerStatus
| summarize Start = any(PodCreationTimeStamp), arg_max(PodStartTime, Namespace) by Name
| extend PodStartTime = iff(isnull(PodStartTime), now(), PodStartTime)
| extend PendingTime = PodStartTime - Start
| project Name, Namespace ,PendingTime

Hitta i KubePodInventory

Hitta i KubePodInventory för att söka efter ett specifikt värde i KubePodInventory-tabellen./nObservera att den här frågan kräver att parametern <SearchValue> uppdateras för att ge resultat.

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
KubePodInventory
| where * contains tostring(SearchValue)
| take 1000