Frågor för AzureMetrics-tabellen

Information om hur du använder dessa frågor i Azure-portalen finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Cirkeldiagram över HTTP-svarskoder

Uppdelning av svarskoder för varje mått under de senaste 12 timmarna.

AzureMetrics 
| where TimeGenerated > ago(12h)  
| where MetricName in ("Http2xx", "Http3xx", "Http4xx", "Http5xx") 
| summarize sum(Total) by MetricName  
| render piechart

Linjediagram över svarstider

Tidsserier för genomsnittlig svarstid (över 5 minuters intervall).

AzureMetrics 
| extend timeBin = bin(TimeGenerated, 5m) 
| summarize ResponseTime = sumif(Average, MetricName=="AverageResponseTime") by timeBin, bin(TimeGenerated, 1h) 
| sort by TimeGenerated desc 
| render timechart

[Klassisk] Hitta i AzureMetrics

[Klassisk] Sök i AzureMetrics för att söka efter ett specifikt värde i azuremetrics-tabellen./nAnteckning om att den här frågan kräver att seachValue-parametern< uppdateras >för att generera resultat

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

Senaste måtten

Visa de senaste måttrapporterna för varje rapporterat mått.

AzureMetrics 
| summarize arg_max(TimeGenerated, UnitName, Total, Count, Maximum, Minimum, Average) by MetricName

Hitta i AzureMetrics

Sök i AzureMetrics för att söka efter ett specifikt värde i azuremetrics-tabellen./nAnteckning om att den här frågan kräver att seachValue-parametern< uppdateras >för att generera resultat

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

ExpressRoute Circuit BitsInPerSecond-trafikdiagram

Trafikdiagram BitsInPerSecond (senaste en timme).

AzureMetrics
| where MetricName == "BitsInPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

ExpressRoute Circuit BitsOutPerSecond-trafikdiagram

Trafikdiagram BitsOutPerSecond (senaste en timme).

AzureMetrics
| where MetricName == "BitsOutPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

ExpressRoute Circuit ArpAvailability-grafen

Trafikdiagram för ArpAvailability (5 minuter).

AzureMetrics
| where MetricName == "ArpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

ExpressRoute Circuit BGP-tillgänglighet

Trafikdiagram för BgpAvailability (5 minuter).

AzureMetrics
| where MetricName == "BgpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

Genomsnittlig CPU-användning

Genomsnittlig CPU-användning under den senaste timmen efter resursnamn.

//consistently high averages could indicate a customer needs to move to a larger SKU
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL" // /DATABASES
| where TimeGenerated >= ago(60min)
| where MetricName in ('cpu_percent') 
| parse _ResourceId with * "/microsoft.sql/servers/" Resource  // subtract Resource name for _ResourceId
| summarize CPU_Maximum_last15mins = max(Maximum), CPU_Minimum_last15mins = min(Minimum), CPU_Average_last15mins = avg(Average) by Resource , MetricName

Prestandafelsökning

Potentiella frågor eller dödlägen i systemet kan leda till dålig prestanda.

//potentially a query or deadlock on the system that could lead to poor performance
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >=ago(60min)
| where MetricName in ('deadlock')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource // subtract Resource name for _ResourceId
| summarize Deadlock_max_60Mins = max(Maximum) by Resource, MetricName

Läser in data

Övervaka datainläsning under den senaste timmen.

AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >= ago(60min)
| where MetricName in ('log_write_percent')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource// subtract Resource name for _ResourceId
| summarize Log_Maximum_last60mins = max(Maximum), Log_Minimum_last60mins = min(Minimum), Log_Average_last60mins = avg(Average) by Resource, MetricName

Antal P2S-anslutningar

Antal aktiva P2S-anslutningar under de senaste 30 dagarna.

AzureMetrics 
| where TimeGenerated > ago(30d)
| where MetricName == "P2SConnectionCount"
| summarize by Maximum, bin(TimeGenerated,1h), Resource
| render timechart

P2S-bandbreddsanvändning

Genomsnittlig P2S-bandbreddsanvändning under de senaste 12 timmarna i bitar/sekund.

AzureMetrics
| where TimeGenerated > ago(24h)
| where MetricName == "P2SBandwidth" 
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Gateway-genomströmning

Aggregera gatewayens dataflöde i byte/s.

AzureMetrics 
| where TimeGenerated > ago(24h)
| where MetricName == "AverageBandwidth"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Visa loggar från AzureMetrics-tabellen

Visar de senaste loggarna i AzureMetrics-tabellen, sorterade efter tid (senaste först).

AzureMetrics
| top 10 by TimeGenerated

Visa loggar från AzureMetrics-tabellen

Visar de senaste loggarna i AzureMetrics-tabellen, sorterade efter tid (senaste först).

AzureMetrics
| top 10 by TimeGenerated

Klustertillgänglighet (KeepAlive)

Visa klustrets tillgänglighet under den senaste timmen.

// To create an alert for this query, click '+ New alert rule'
AzureMetrics 
| where ResourceProvider == "MICROSOFT.KUSTO"
| where TimeGenerated > ago(1d)
| where MetricName == "KeepAlive"
| parse _ResourceId with * "providers/microsoft.kusto/clusters/" cluster_name // Get the cluster name from the ResourceId string
| summarize heartbeat_count = count() by bin(TimeGenerated, 30m), cluster_name // bin is used to set the time grain to 30 minutes
| extend alive=iff(heartbeat_count > 0, true, false)
| sort by TimeGenerated asc // sort the results by time (ascending order)