Frågor för ASCDeviceEvents-tabellen

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Fel vid autentisering och attestering av Azure Sphere-enheter

En lista över autentiserings- och attesteringsfel för Azure Sphere-enheter för den senaste veckan, sorterade efter tid.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and
        Properties.EventType == "DeviceAttestationFailure" or Properties.EventType == "DeviceCertificateEvent" and
        ResultType == "Failure" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| project TimeGenerated, DeviceId, Properties, ResultDescription, Location
| sort by TimeGenerated desc
| limit 100

Tidslinje för Azure Sphere-enhetshändelser

En sorterad tidslinje för alla händelser som genererats av en Azure Sphere-enhet under den senaste veckan för att övervaka och felsöka oväntade fel.

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" or Properties.DeviceTelemetryEventCategory == "AppCrash" // Remove/Add filters to see all/specific events. Filter data by Device by adding " | where DeviceId == "Your Device ID" " 
| project TimeGenerated, OperationName, ResultType, ResultDescription, Properties, Location
| sort by TimeGenerated desc
| limit 100

Tidsschema för händelser i Azure Sphere-enhetens pulsslag

Ett tidsschema för alla certifikatgenereringshändelser som initierats av Azure Sphere-enheter under den senaste veckan för att kontinuerligt övervaka enhetens hälsa och se trender.

let Interval = timespan(1d); // Interval for the Chart 
ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and 
        Properties.EventType == "DeviceCertificatesGenerate" and 
        ResultType == "Success"
| summarize Device_Heartbeat_Events=count() by bin(TimeGenerated, Interval)
| render timechart

Azure Sphere-enheter som inte har uppdaterats till det senaste operativsystemet

En lista över Azure Sphere-enheter som inte har uppdaterats till den senaste os-versionen under den senaste veckan.

ASCDeviceEvents
| where OperationName == "DeviceUpdateEvent" and  
        todouble(Properties.InstalledOSVersion) != todouble(Properties.TargetedOSVersion) // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize by DeviceId
| limit 100

Sammanfattning av telemetrihändelser för Azure Sphere-enheter

Ett cirkeldiagram som sammanfattar andelen för var och en av de händelsekategorier som genererats av Azure Sphere-enheter under den senaste veckan, för att övervaka enhetens övergripande hälsa.

ASCDeviceEvents
| where OperationName == "DeviceTelemetryEvent" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize count() by tostring(Properties.DeviceTelemetryEventCategory)
| render piechart