Förfrågningar för tabellen AEWExperimentAssignmentSummary

Information om hur du använder dessa frågor i Azure-portalen finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Variantfördelning efter funktioner

Lista det totala antalet uppdrag för varje variant i funktionsallokeringar.

// Variant assignment counts by features
AEWExperimentAssignmentSummary
| summarize
    IsControlVariant = take_any(IsControlVariant),
    AllocationPercentage = take_any(AllocationPercentage),
    AssignmentEventCount = sum(AssignmentEventCount),
    EarliestAssignment = min(MinTimeGenerated),
    LatestAssignment = max(MaxTimeGenerated)
    by FeatureName, AllocationId, Variant
| order by FeatureName asc, LatestAssignment desc, Variant asc

Senaste poängkortsmetadata för en given funktion

Hämta den senaste metadata från experimentscorecard för en given funktion.

// Latest scorecard metadata for a given feature
// set the feature flag name to query
let QueryFeature = "MyFeatureFlag";
AEWExperimentAssignmentSummary
| where FeatureName == QueryFeature
| summarize MaxTimeGenerated=max(MaxTimeGenerated), Variants=make_set(Variant, 1000) by AllocationId
| summarize arg_max(MaxTimeGenerated, *)
| join kind=inner AEWExperimentScorecards on AllocationId
| summarize arg_max(TimeGenerated, ScorecardId)
| project
    FeatureName, AllocationId, Variants,
    ScorecardId, AnalysisStartTime, AnalysisEndTime, Insights

Senaste resultat på poängtavlan för en given funktion

Fråga efter den senaste experimentresultatrapporten för en given funktion.

// Latest scorecard results for a given feature
// set the feature flag name to query
let QueryFeature = "MyFeatureFlag";
AEWExperimentAssignmentSummary
| where FeatureName == QueryFeature
| summarize arg_max(MaxTimeGenerated, AllocationId)
| join kind=inner AEWExperimentScorecards on AllocationId
| summarize arg_max(TimeGenerated, ScorecardId)
| join kind=inner AEWExperimentScorecardMetricPairs on ScorecardId
| project
    ScorecardId, MetricId, MetricDisplayName, MetricKind, MetricTags,
    TreatmentVariant, TreatmentCount, TreatmentMetricValue,
    ControlVariant, ControlCount, ControlMetricValue,
    TreatmentEffect, RelativeDifference, PValue, Insights