Frågor för tabellen ACSCallRecordingSummary

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Histogram för samtalsinspelningsvaraktighet

Genererar ett histogram med varaktigheter för samtalsinspelning i sekunder.

ACSCallRecordingSummary
| distinct RecordingId, RecordingLength
// Count call duration bins (60 second intervals)
| summarize duration_counts=count() by bin(RecordingLength, 6000)
| order by RecordingLength asc
| render columnchart with (xcolumn = RecordingLength, title="Recording duration histogram")

Samtalsinspelningsvaraktighetens percentiler

Beräknar varaktigheten för genomsnittlig samtalsinspelning i sekunder, samt percentilerna 50 %, 90 % och 99 % samtalsvaraktighet.

ACSCallRecordingSummary
// Get the distinct combinations of RecordingId, RecordingLength
| distinct RecordingId, RecordingLength
// Calculate average and percentiles (50%, 90%, and 99%) of call durations (in seconds)
| summarize avg(RecordingLength), percentiles(RecordingLength, 50, 90, 99)

Samtalsinspelningens slutorsaksförhållande

Skapar ett cirkeldiagram över fördelningen av orsaker till avslut av samtalsinspelningar.

ACSCallRecordingSummary
// Count distinct calls (dcount(CorrelationId)) per call type
| summarize call_types=dcount(RecordingId) by RecordingEndReason
| render piechart title="Recording End Reason Ratio"

Dagliga samtalsinspelningar

Producerar ett histogram över inspelningar som gjorts per dag under den senaste veckan.

ACSCallRecordingSummary
// To filter out recordings made over a week ago, uncomment the next line
// | where TimeGenerated > ago(7d)
// Get the distinct combinations of RecordingId and CallStartTime
| distinct RecordingId, TimeGenerated
// Adds a new column with the call start day
| extend day = floor(TimeGenerated, 1d)
// Count the number of calls per day
| summarize event_count=count() by day
| sort by day asc
| render columnchart title="Number of recordings per day"

Samtalsinspelningar varje timme

Genererar ett histogram med inspelningar som gjorts per timme under den senaste dagen.

    ACSCallRecordingSummary
    // To filter out recordings made over a day ago, uncomment the next line
    | where TimeGenerated > ago(1d)
    // Get the distinct combinations of RecordingId and TimeGenerated
    | distinct RecordingId, TimeGenerated
    // Adds a new column with the call start hour
    | extend hour = floor(TimeGenerated, 1h)
    // Count the number of calls per hour
    | summarize event_count=count() by hour
    | sort by hour asc
    | render columnchart title="Number of recordings per hour in last day"

Förhållandet mellan samtalsinspelningens lägen

Skapar ett cirkeldiagram över andelen inspelningslägen (innehålls-/formattyper).

ACSCallRecordingSummary
| summarize count() by ContentType, FormatType
| extend ContentFormat = strcat(ContentType, "/", FormatType)
| project ContentFormat, count_
| render piechart title="Recording by mode (content/format types)"