Frågor för tabellen ACSCallDiagnosticsUpdates

För information om hur du använder dessa frågor i Azure-portalen, se Log Analytics tutorial. Information om REST-API:et finns i Fråga.

Medietypsförhållande

Skapar ett cirkeldiagram över andelen strömmar av en viss medietyp.

ACSCallDiagnosticsUpdates
// Count the number of streams per media type
| summarize media_types=count() by MediaType
| render piechart title="Media Type Ratio"

Transporttypsförhållande

Skapar ett cirkeldiagram över andelen strömmar med hjälp av en viss transporttyp.

ACSCallDiagnosticsUpdates
// Count the number of streams per transport type
| summarize transport_types=count() by TransportType
| render piechart title="Transport Type Ratio"

Genomsnittliga telemetrivärden

Beräknar genomsnittsvärdena för de sex telemetrifälten.

ACSCallDiagnosticsUpdates
// Calculate the average value for each of the six telemetry fields
| summarize Avg_JitterAvg=avg(JitterAvg),
            Avg_JitterMax=avg(JitterMax),
            Avg_RoundTripTimeAvg=avg(RoundTripTimeAvg),
            Avg_RoundTripTimeMax=avg(RoundTripTimeMax),
            Avg_PacketLossRateAvg=avg(PacketLossRateAvg),
            Avg_PacketLossRateMax=avg(PacketLossRateMax)

Jitter genomsnittligt histogram

Genererar ett histogram med genomsnittlig jitter per ström.

ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(JitterAvg)
// Count jitter values by 10 millisecond intervals
| summarize JitterAvg_counts=count() by bin(JitterAvg, 10)
| order by JitterAvg asc
| render columnchart with (xcolumn = JitterAvg, title="JitterAvg histogram")

Jitter max histogram

Skapar ett histogram med maximal jitter per ström.

ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(JitterMax)
// Count jitter values by 10 millisecond intervals
|summarize JitterMax_counts=count() by JitterMax
| order by JitterMax asc
| render columnchart with (xcolumn = JitterMax, title="JitterMax histogram")

Genomsnittligt histogram för paketförlust

Genererar ett histogram med genomsnittlig paketförlustfrekvens per dataström.

ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(PacketLossRateAvg)
// Count packet loss rate values within an inverval of 0.01 (1%)
| summarize PacketLossRateAvg_counts=count() by bin(PacketLossRateAvg, 0.01)
| order by PacketLossRateAvg asc
| render columnchart with (xcolumn = PacketLossRateAvg, title="PacketLossRateAvg histogram")

Histogram för maximal paketförlustfrekvens

Genererar ett histogram med maximal paketförlustfrekvens per ström.

ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(PacketLossRateMax)
// Count packet loss rate values within an inverval of 0.01 (1%)
| summarize PacketLossRateMax_counts=count() by bin(PacketLossRateMax, 0.01)
| order by PacketLossRateMax asc
| render columnchart with (xcolumn = PacketLossRateMax, title="PacketLossRateMax histogram")

Genomsnittligt histogram för tur och retur-tid

Skapar ett histogram med genomsnittlig tur- och returtid per ström.

// RoundTripTime Average Histogram
ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(RoundTripTimeAvg)
// Count round trip time values by 10 millisecond intervals
|summarize RoundTripTimeAvg_counts=count() by bin(RoundTripTimeAvg, 10)
| order by RoundTripTimeAvg asc
| render columnchart with (xcolumn = RoundTripTimeAvg, title="RoundTripTimeAvg histogram")

Maximihistogram för tur- och returtid

Genererar ett histogram med maximal tur och retur-tid per ström.

ACSCallDiagnosticsUpdates
// Filter null values
| where isnotnull(RoundTripTimeMax)
// Count round trip time values by 10 millisecond intervals
|summarize RoundTripTimeMax_counts=count() by bin(RoundTripTimeMax, 10)
| order by RoundTripTimeMax asc
| render columnchart with (xcolumn = RoundTripTimeMax, title="RoundTripTimeMax histogram")

Jitterkvalitetsförhållande

Producerar ett cirkeldiagram över andelen strömmar med bra eller dålig jitterkvalitet.

ACSCallDiagnosticsUpdates
// Classify the jitter quality as Poor or Good based on
// whether the average jitter is higher than 30 milliseconds
| project JitterQuality = iff(JitterAvg > 30, "Poor", "Good")
// Counts the number of streams per jitter quality
| summarize count() by JitterQuality
| render piechart title="Jitter Quality"

Kvalitetsförhållande för paketförlust

Skapar ett cirkeldiagram över andelen strömmar med god eller dålig paketförlustfrekvenskvalitet.

ACSCallDiagnosticsUpdates
// Classify packet loss rate quality as Poor or Good based on
// whether the average packet loss rate is higher than 10%
| project PacketLossRateQuality = iff(PacketLossRateAvg > 0.1, "Poor", "Good")
// Count the number of streams per packet loss rate quality
| summarize count() by PacketLossRateQuality
| render piechart title="Packet Loss Rate Quality"

Kvalitetsgrad för tur och retur-tid

Producerar ett cirkeldiagram över andelen strömmar med god eller dålig tur- och returtidskvalitet.

ACSCallDiagnosticsUpdates
// Classifying the round trip time quality as Poor or Good based on
// whether the average round trip time is higher than 500 milliseconds
| project RoundTripTimeQuality = iff(RoundTripTimeAvg > 500, "Poor", "Good")
// Count the number of streams per round trip time quality
| summarize count() by RoundTripTimeQuality
| render piechart title="Round Trip Time Quality"