Frågor för tabellen ACSCallAutomationIncomingOperations

Information om hur du använder dessa frågor i Azure-portalen finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Automatisering av operationer

Returnerar alla distinkta kombinationer av anropsautomatiseringsåtgärder och versionspar.

ACSCallAutomationIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Beräkna varaktighetsprocentiler för samtalsautomatiserings-operation

Beräknar den 90:e, 95:e och 99:e percentilen av körningens varaktighet i millisekunder för varje anropsautomatiseringsåtgärd. Det kan anpassas för att köras för en enda åtgärd eller för andra percentiler.

ACSCallAutomationIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

De 5 främsta IP-adresserna per samtalsautomatisering

För varje automatiseringsåtgärd för samtal, hämta de fem IP-adresser som har utmärkt sig mest med att anropa den åtgärden.

ACSCallAutomationIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Anropa automationsdriftsfel

Visa en lista över varje anropsautomatiseringsfel som sorteras efter senaste.

ACSCallAutomationIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

Antal resultat för samtalsautomatiseringsåtgärd

Räkna de typer av returnerade resultat som returneras för varje anropsautomatiseringsåtgärd.

ACSCallAutomationIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Call Automation-loggfiler för samtalsanslutnings-ID

Frågor Anropa Automation-loggar för ett visst samtalsanslutnings-ID.

ACSCallAutomationIncomingOperations
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| limit 100

Kör Automation API-åtgärder under ett samtal

Returnerar alla Call Automation API-åtgärder och versionspar för ett specifikt anrop (korrelations-ID).

ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| project CorrelationId, OperationName, OperationVersion
| limit 100

CallDiagnostics-logg för CallAutomation API-anrop

Förfrågar diagnostikloggen angående ett samtal som interagerades med av API för samtalsautomatisering med korrelations-ID.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallDiagnostics)
    on CorrelationId
| limit 100

CallSummary-logg för CallAutomation API-anrop

Frågar sammanfattningsloggen efter ett anrop som interagerades med av Api för samtalsautomatisering med hjälp av korrelations-ID.

ACSCallAutomationIncomingOperations 
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
    (ACSCallSummary)
    on CorrelationId
| limit 100

Antal anrop med MediaStreaming aktivt

Beräknar antalet anrop som hade MediaStreaming aktivt.

ACSCallAutomationStreamingUsage 
    | where StreamingModality contains "AudioStreaming" 
    | summarize NumCallsWithMediaStreamingActive = dcount(CallConnectionId) 

Antal lyckade MediaStreaming-åtgärder

Beräknar antalet lyckade MediaStreaming-åtgärder.

ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API. 
    | where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
    | where tostring(ResultSignature) matches regex "2.."
    | summarize MediaStreamingSuccess=count() by ResultSignature

Antal misslyckade mediastreaming-operationer

Beräknar antalet fel i MediaStreaming-åtgärden.

ACSCallAutomationIncomingOperations 
// Filter OperationName to view results for each API.
    | where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
    | where tostring(ResultSignature) matches regex "5.."
    | summarize MediaStreamingFailures=count() by ResultSignature

Antal anrop med Transkription aktivt

Beräknar antalet anrop som hade Transkription aktivt.

ACSCallAutomationStreamingUsage 
    | where StreamingModality == "Transcription" 
    | summarize NumCallsWithTranscriptionActive = dcount(CallConnectionId)

Antal lyckade transkriptionsåtgärder

Beräknar antalet lyckade transkriptionsåtgärder.

ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
    | where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
    | where tostring(ResultSignature) matches regex "2.."
    | summarize TranscriptionSuccess=count()

Antal misslyckade transkriptionsåtgärder

Beräknar antalet fel i transkriptionsåtgärden.

ACSCallAutomationIncomingOperations 
// Filter OperationName to view results for each API.
    | where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
    | where tostring(ResultSignature) matches regex "5.."
    | summarize TranscriptionFailures=count()