Snabbstart: Skapa en Azure API Management-instans med Terraform

GÄLLER FÖR: Alla API Management-nivåer

Den här artikeln visar hur du använder Terraform för att skapa en API Management-instans i Azure. Du kan också använda Terraform för vanliga hanteringsuppgifter som att importera API:er i din API Management-instans.

Azure API Management hjälper organisationer att publicera API:er till externa utvecklare, partner och interna utvecklare för att frigöra potentialen för sina data och tjänster. API Management lägger grunden till ett effektivt API-program genom engagerade utvecklare, affärsinsikter, analyser, hög säkerhet och skydd. Med API Management skapar och hanterar du moderna API-gatewayer för befintliga serverdelstjänster var som helst.

Terraform möjliggör definition, förhandsversion och distribution av molninfrastruktur. Med Terraform skapar du konfigurationsfiler med hjälp av HCL-syntax. Med HCL-syntaxen kan du ange molnleverantören – till exempel Azure – och de element som utgör din molninfrastruktur. När du har skapat konfigurationsfilerna skapar du en körningsplan som gör att du kan förhandsgranska ändringarna i infrastrukturen innan de distribueras. När du har verifierat ändringarna tillämpar du planen för att köra och distribuera infrastrukturen.

I den här artikeln kan du se hur du:

Förutsättningar

• Om du inte har en Azure-prenumeration skapar du ett kostnadsfritt konto innan du börjar.

• Installera och konfigurera Terraform

• För Azure CLI:

  • Använd Bash-miljön i Azure Cloud Shell. Mer information finns i Komma igång med Azure Cloud Shell.

    

  • Om du föredrar att köra CLI-referenskommandon lokalt installerar du Azure CLI. Om du kör i Windows eller macOS kan du köra Azure CLI i en Docker-container. Mer information finns i Så här kör du Azure CLI i en Docker-container.

    • Om du använder en lokal installation loggar du in på Azure CLI med kommandot az login . Slutför autentiseringsprocessen genom att följa stegen som visas i terminalen. Andra inloggningsalternativ finns i Autentisera till Azure med Azure CLI.

    • När du uppmanas att installera Azure CLI-tillägget vid första användningen. Mer information om tillägg finns i Använda och hantera tillägg med Azure CLI.

    • Kör az version för att hitta den version och beroende bibliotek som är installerade. För att uppgradera till den senaste versionen, kör az upgrade.

• För Azure PowerShell:

  • Om du väljer att använda Azure PowerShell lokalt:
    • Installera den senaste versionen av Az PowerShell-modulen.
    • Anslut till ditt Azure-konto med hjälp av cmdleten Connect-AzAccount .
  • Om du väljer att använda Azure Cloud Shell:
    • Mer information finns i Översikt över Azure Cloud Shell .

Implementera Terraformskriptet

1. Skapa en katalog där du kan testa och köra Terraform-exempelkoden och göra den till den aktuella katalogen.

2. Skapa en fil med namnet main.tf och infoga följande kod:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_api_management_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_api_management" "api" {
     name                = "apiservice${random_string.azurerm_api_management_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     publisher_email     = var.publisher_email
     publisher_name      = var.publisher_name
     sku_name            = "${var.sku_name}_${var.sku_count}"
   }
   

3. Skapa en fil med namnet outputs.tf och infoga följande kod:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "api_management_service_name" {
     value = azurerm_api_management.api.name
   }
   

4. Skapa en fil med namnet providers.tf och infoga följande kod:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>4.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Skapa en fil med namnet variables.tf och infoga följande kod:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "publisher_email" {
     default     = "test@contoso.com"
     description = "The email address of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_email) > 0
       error_message = "The publisher_email must contain at least one character."
     }
   }
   
   variable "publisher_name" {
     default     = "publisher"
     description = "The name of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_name) > 0
       error_message = "The publisher_name must contain at least one character."
     }
   }
   
   variable "sku_name" {
     description = "The pricing tier of this API Management service"
     default     = "BasicV2"
     type        = string
     validation {
       condition     = contains(["Basic", "BasicV2", "Consumption", "Developer", "Premium", "PremiumV2", "Standard", "StandardV2"], var.sku_name)
       error_message = "The sku must be one of the following: Basic, BasicV2, Consumption, Developer, Premium, PremiumV2, Standard, StandardV2."
     }
   }
   
   variable "sku_count" {
     description = "The instance size of this API Management service."
     default     = 1
     type        = number
     validation {
       condition     = contains([1, 2], var.sku_count)
       error_message = "The sku_count must be one of the following: 1, 2."
     }
   }
   

Initiera Terraform

Kör terraform init för att initiera Terraform-distributionen. Det här kommandot laddar ned den Azure-provider som krävs för att hantera dina Azure-resurser.

terraform init -upgrade

Viktiga punkter:

• Parametern -upgrade uppgraderar nödvändiga provider-plugin-program till den senaste versionen som uppfyller konfigurationens versionsbegränsningar.

Skapa en Terraform-körningsplan

Kör terraform plan för att skapa en körningsplan.

terraform plan -out main.tfplan

Viktiga punkter:

• Kommandot terraform plan skapar en körningsplan, men kör den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om exekveringsplanen matchar dina förväntningar innan du gör några ändringar av resurserna i verkligheten.
• Med den valfria -out parametern kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att planen du granskade är exakt vad som tillämpas.

Tillämpa en Terraform-körningsplan

Kör terraform apply för att tillämpa exekveringsplanen på din molninfrastruktur.

terraform apply main.tfplan

Viktiga punkter:

• terraform apply Exempelkommandot förutsätter att du tidigare körde terraform plan -out main.tfplan.
• Om du har angett ett annat filnamn för parametern -out använder du samma filnamn i anropet till terraform apply.
• Om du inte använde parametern -out anropar terraform apply du utan några parametrar.

Verifiera resultatet

Rensa resurser

Gör följande när du inte längre behöver de resurser som skapats via Terraform:

1. Kör terraform plan och ange destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Viktiga punkter:

   • Kommandot terraform plan skapar en körningsplan, men kör den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om exekveringsplanen matchar dina förväntningar innan du gör några ändringar av resurserna i verkligheten.
   • Med den valfria -out parametern kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att planen du granskade är exakt vad som tillämpas.

2. Kör terraform apply för att genomföra körningsplanen.

   terraform apply main.destroy.tfplan
   

Felsöka Terraform i Azure

Felsöka vanliga problem när du använder Terraform i Azure

Nästa steg