Lambda-functies voor Bicep

In dit artikel worden de lambda-functies beschreven die in Bicep moeten worden gebruikt. Lambda-expressies (of lambda-functies) zijn in wezen blokken code die als argument kunnen worden doorgegeven. Ze kunnen meerdere parameters gebruiken, maar zijn beperkt tot één regel code. In Bicep heeft lambda-expressie deze indeling:

<lambda variable> => <expression>

Beperkingen

De functie Bicep lambda heeft deze beperkingen:

• Lambda-expressie kan alleen rechtstreeks worden opgegeven als functieargumenten in deze functies: filter(), , groupBy()mapValues()map(), , reduce(), , , sort()en .toObject()
• Het gebruik van lambda-variabelen (de tijdelijke variabelen die worden gebruikt in de lambda-expressies) binnen resource- of modulematrixtoegang wordt momenteel niet ondersteund.
• Het gebruik van lambda-variabelen in de listKeys functie wordt momenteel niet ondersteund.
• Het gebruik van lambda-variabelen in de referentiefunctie wordt momenteel niet ondersteund.

filter

filter(inputArray, lambda expression)

Hiermee filtert u een matrix met een aangepaste filterfunctie.

Naamruimte: sys.

Parameters

Retourwaarde

Een matrix.

Voorbeelden

In de volgende voorbeelden ziet u hoe u de filter functie gebruikt.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Cira'
    age: 8
    interests: ['Rubs']
  }
]

output oldDogs array = filter(dogs, dog => dog.age >=5)
output dogNameIndex array = filter(dogs, (val, i) => i < 2 && substring(val.name, 0, 1) == 'C')

De uitvoer uit het vorige voorbeeld:

oldDogs vermeldt de honden die vijf of ouder zijn; dogNameIndex identificeert de honden waarvan het indexnummer kleiner is dan twee en waarvan de naam begint met de letter C.

var itemForLoop = [for item in range(0, 10): item]

output filteredLoop array = filter(itemForLoop, i => i > 5)
output isEven array = filter(range(0, 10), i => 0 == i % 2)

De uitvoer uit het vorige voorbeeld:

filterdLoop toont de getallen in een matrix die groter is dan 5; en isEven toont de even getallen in de matrix.

groupBy

groupBy(inputArray, lambda expression)

Hiermee maakt u een object met matrixwaarden van een matrix met behulp van een groeperingsvoorwaarde.

Naamruimte: sys.

Parameters

Retourwaarde

Een object.

Voorbeelden

In het volgende voorbeeld ziet u hoe u de groupBy functie gebruikt.

var inputArray = ['foo', 'bar', 'baz']

output outObject object = groupBy(inputArray, x => substring(x, 0, 1)) 

De uitvoer uit het vorige voorbeeld:

outObject toont een object waarmee de matrixelementen worden gegroepeerd op basis van de eerste letters.

map

map(inputArray, lambda expression)

Hiermee past u een aangepaste toewijzingsfunctie toe op elk element van een matrix.

Naamruimte: sys.

Parameters

Retourwaarde

Een matrix.

Opmerking

In het volgende voorbeeld ziet u hoe u de map functie gebruikt.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]

output dogNames array = map(dogs, dog => dog.name)
output sayHi array = map(dogs, dog => 'Hello ${dog.name}!')
output mapArray array = map(range(0, length(dogs)), i => {
  i: i
  dog: dogs[i].name
  greeting: 'Ahoy, ${dogs[i].name}!'
})
output mapArrayIndex array = map(dogs, (x, i) => { index: i, val: x.name})

De uitvoer uit het vorige voorbeeld zijn:

dogNames toont de namen van de honden uit de matrix van objecten; sayHi voegt "Hallo" en elk van de namen van de honden samen; mapArray en mapArrayIndex maken nog twee matrices van objecten.

mapValues

mapValues(inputObject, lambda expression)

Hiermee maakt u een object op basis van een invoerobject met behulp van een lambda-expressie om waarden toe te wijzen.

Naamruimte: sys.

Parameters

Retourwaarde

Een object.

Opmerking

In het volgende voorbeeld ziet u hoe u de mapValues functie gebruikt.

var inputObject = { foo: 'foo', bar: 'bar' }

output mapObject object = mapValues(inputObject, val => toUpper(val)) 

De uitvoer uit het voorgaande voorbeeld is:

mapObject maakt een ander object met de waarden in hoofdletters.

Verminderen

reduce(inputArray, initialValue, lambda expression)

Vermindert een matrix met een aangepaste reductiefunctie.

Naamruimte: sys.

Parameters

Retourwaarde

Alle.

Opmerking

In de volgende voorbeelden ziet u hoe u de reduce functie gebruikt.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]
var ages = map(dogs, dog => dog.age)
output totalAge int = reduce(ages, 0, (cur, next) => cur + next)
output totalAgeAdd1 int = reduce(ages, 1, (cur, next) => cur + next)
output oddAge int = reduce(ages, 0, (cur, next, i) => (i % 2 == 0) ? cur + next : cur)

De uitvoer uit het vorige voorbeeld zijn:

totalAge telt de leeftijden van de honden op; totalAgeAdd1 heeft een initiële waarde van 1 en voegt alle leeftijden van de hond toe aan de initiële waarden. oddAge telt de leeftijden van honden op die zich op even indexen bevinden, met name 5 (Evie) en 2 (Indy).

output reduceObjectUnion object = reduce([
  { foo: 123 }
  { bar: 456 }
  { baz: 789 }
], {}, (cur, next) => union(cur, next))

De uitvoer uit het voorgaande voorbeeld is:

De samenvoegfunctie retourneert één object met alle elementen uit de parameters. Met de functie worden de sleutelwaardeparen van de objecten samengevoegd in een nieuw object.

sort

sort(inputArray, lambda expression)

Hiermee sorteert u een matrix met een aangepaste sorteerfunctie.

Naamruimte: sys.

Parameters

Retourwaarde

Een matrix.

Opmerking

In het volgende voorbeeld ziet u hoe u de sort functie gebruikt.

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: ['Ball', 'Frisbee']
  }
  {
    name: 'Casper'
    age: 3
    interests: ['Other dogs']
  }
  {
    name: 'Indy'
    age: 2
    interests: ['Butter']
  }
  {
    name: 'Kira'
    age: 8
    interests: ['Rubs']
  }
]

output dogsByAge array = sort(dogs, (a, b) => a.age < b.age)

De uitvoer uit het voorgaande voorbeeld sorteert de hondenobjecten van de jongste naar de oudste:

Toobject

toObject(inputArray, lambda expression, [lambda expression])

Converteert een matrix naar een object met een aangepaste sleutelfunctie en optionele aangepaste waardefunctie. Zie items over het converteren van een object naar een matrix.

Naamruimte: sys.

Parameters

Retourwaarde

Een object.

Opmerking

In het volgende voorbeeld ziet u hoe u de toObject functie gebruikt met de twee vereiste parameters:

var dogs = [
  {
    name: 'Evie'
    age: 5
    interests: [ 'Ball', 'Frisbee' ]
  }
  {
    name: 'Casper'
    age: 3
    interests: [ 'Other dogs' ]
  }
  {
    name: 'Indy'
    age: 2
    interests: [ 'Butter' ]
  }
  {
    name: 'Kira'
    age: 8
    interests: [ 'Rubs' ]
  }
]

output dogsObject object = toObject(dogs, entry => entry.name)

In het voorgaande voorbeeld wordt een object gegenereerd op basis van een matrix.

De volgende toObject functie met de derde parameter biedt dezelfde uitvoer.

output dogsObject object = toObject(dogs, entry => entry.name, entry => entry)

In het volgende voorbeeld ziet u hoe u de toObject functie gebruikt met drie parameters.

var dogs = [
  {
    name: 'Evie'
    properties: {
      age: 5
      interests: [ 'Ball', 'Frisbee' ]
    }
  }
  {
    name: 'Casper'
    properties: {
      age: 3
      interests: [ 'Other dogs' ]
    }
  }
  {
    name: 'Indy'
    properties: {
      age: 2
      interests: [ 'Butter' ]
    }
  }
  {
    name: 'Kira'
    properties: {
      age: 8
      interests: [ 'Rubs' ]
    }
  }
]
output dogsObject object = toObject(dogs, entry => entry.name, entry => entry.properties)

In het voorgaande voorbeeld wordt een object gegenereerd op basis van een matrix.

Volgende stappen

• Zie Bicep-functies : matrices voor meer aan matrices gerelateerde Bicep-functies.