Vragen voor de StorageBlobLogs-tabel

Voor informatie over het gebruik van deze queries in de Azure-portal, zie Log Analytics tutorial. Zie Query voor de REST API.

Meest voorkomende fouten

Geef de 10 meest voorkomende fouten van de afgelopen 3 dagen weer.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

Operaties die de meeste fouten veroorzaken

Lijst de top 10 bewerkingen die de meeste fouten hebben veroorzaakt in de afgelopen 3 dagen.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

Operaties met de hoogste latentie

Maak een lijst van de top 10 bewerkingen met de langste end-to-end latentie over de laatste 3 dagen.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Handelingen die serverzijdevertraging veroorzaken

Geef een overzicht van alle operaties die serverzijde-snelheidsbeperkingsfouten veroorzaakten in de afgelopen 3 dagen.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Toon anonieme verzoeken

Lijst alle verzoeken met anonieme toegang van de afgelopen 3 dagen op.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Diagram van frequente bewerkingen

Een cirkeldiagram van operaties die in de afgelopen 3 dagen zijn gebruikt.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart