Query's voor de CommonSecurityLog-tabel

Zie de zelfstudie over Log Analytics voor meer informatie over het gebruik van deze query's in Azure Portal. Zie Query voor de REST API.

Gebruik van Palo Alto Collector-machines

Deze query geeft een aflopende lijst weer van de hostnaam van alle collectormachines op basis van de hoeveelheid gebeurtenissen die ze ontvangen van een Palo Alto-apparaat.

CommonSecurityLog
// Quering on the past 7 days
| where TimeGenerated > ago(7d)
// Quering only on incoming events from a Palo Alto appliance
| where DeviceProduct has 'PAN-OS'
| where DeviceVendor =~ 'Palo Alto Networks'
// Find the the collector machine with the highest usage
| summarize Count=count() by Computer
// Sort in a descending order- Most used Collector hostname comes first
| sort by Count desc

Gebruik van Cisco ASA-gebeurtenissentype

Deze query geeft een aflopende lijst weer van de hoeveelheid gebeurtenissen die zijn opgenomen voor elke DeviceEventClassID

CommonSecurityLog 
// Quering on the past 7 days
| where TimeGenerated > ago(7d)
// Only filter on Cisco ASA events
| where DeviceVendor == "Cisco" and DeviceProduct == "ASA"
// group events by their DeviceEventClassID value, which represents the Cisco message id
| summarize count_events=count() by DeviceEventClassID
// Sort in a descending order- most used DeviceEventClassID comes first
| sort by count_events desc

Volumestatistieken voor apparaat gebeurtenissen

Apparaten die de meeste gebeurtenissen verzenden.

CommonSecurityLog
| top-nested 15 of DeviceVendor by Vendor=count(),
  top-nested 5 of DeviceProduct by Product=count(),
  top-nested 5 of DeviceVersion by Version=count()