Exercise - Create and use a module

You've been tasked with adding a content delivery network, or CDN, to your company's website for the launch of a toy wombat. However, other teams in your company have told you they don't need a CDN. In this exercise, you'll create modules for the website and the CDN, and you'll add the modules to a template.

During the process, you'll:

This exercise uses the Bicep extension for Visual Studio Code. Be sure to install this extension in Visual Studio Code.

Create a blank Bicep file

1. Open Visual Studio Code.

2. Create a new file called main.bicep.

3. Save the empty file so that Visual Studio Code loads the Bicep tooling.

   You can either select File > Save As or select Ctrl+S on Windows (⌘+S on macOS). Be sure to remember where you save the file. For example, you might want to create a templates folder to save it in.

Create a module for your application

1. Create a new folder called modules in the same folder where you created your main.bicep file. In the modules folder, create a file called app.bicep. Save the file.

2. Add the following content into the app.bicep file:

   @description('The Azure region into which the resources should be deployed.')
   param location string
   
   @description('The name of the App Service app.')
   param appServiceAppName string
   
   @description('The name of the App Service plan.')
   param appServicePlanName string
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string
   
   resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSkuName
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   
   @description('The default host name of the App Service app.')
   output appServiceAppHostName string = appServiceApp.properties.defaultHostName
   

   This file deploys an Azure App Service plan and an app. Notice that the module is fairly generic. It doesn't include any assumptions about the names of resources, or the App Service plan's SKU. This makes it easy to reuse the module for different deployments.

3. Save the changes to the file.

Add the module to your Bicep template

Here, you add the app module to your Bicep template as a starting point.

1. Open the main.bicep file.

2. Add the following parameters and variable to the file:

   @description('The Azure region into which the resources should be deployed.')
   param location string = 'westus3'
   
   @description('The name of the App Service app.')
   param appServiceAppName string = 'toy-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string = 'F1'
   
   var appServicePlanName = 'toy-product-launch-plan'
   

   Because this is the template that you intend to deploy for your toy websites, it's a little more specific. The App Service plan name is defined as a variable. The SKU parameter has a default value that makes sense for the toy launch website.

3. Below the parameters, create a blank line. Now, type the first line of the app module definition:

   module app 'modules/app.bicep' = {
   

   As you type, notice that the Bicep extension for Visual Studio Code helps you to scaffold the module declaration. When you type the path to your module and type the equals (=) character, a pop-up menu appears with several options.

4. Select Required properties from the pop-up menu:

   

5. Complete the module declaration:

   module app 'modules/app.bicep' = {
     name: 'toy-launch-app'
     params: {
       appServiceAppName: appServiceAppName
       appServicePlanName: appServicePlanName
       appServicePlanSkuName: appServicePlanSkuName
       location: location
     }
   }
   

6. At the bottom of the file, define an output:

   @description('The host name to use to access the website.')
   output websiteHostName string = app.outputs.appServiceAppHostName
   

7. Save the changes to the file.

Create a module for the content delivery network

1. In the modules folder, create a file called cdn.bicep. Save the file.

2. Add the following content into the cdn.bicep file:

   @description('The host name (address) of the origin server.')
   param originHostName string
   
   @description('The name of the CDN profile.')
   param profileName string = 'cdn-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the CDN endpoint')
   param endpointName string = 'endpoint-${uniqueString(resourceGroup().id)}'
   
   @description('Indicates whether the CDN endpoint requires HTTPS connections.')
   param httpsOnly bool
   
   var originName = 'my-origin'
   
   resource cdnProfile 'Microsoft.Cdn/profiles@2024-09-01' = {
     name: profileName
     location: 'global'
     sku: {
       name: 'Standard_Microsoft'
     }
   }
   
   resource endpoint 'Microsoft.Cdn/profiles/endpoints@2024-09-01' = {
     parent: cdnProfile
     name: endpointName
     location: 'global'
     properties: {
       originHostHeader: originHostName
       isHttpAllowed: !httpsOnly
       isHttpsAllowed: true
       queryStringCachingBehavior: 'IgnoreQueryString'
       contentTypesToCompress: [
         'text/plain'
         'text/html'
         'text/css'
         'application/x-javascript'
         'text/javascript'
       ]
       isCompressionEnabled: true
       origins: [
         {
           name: originName
           properties: {
             hostName: originHostName
           }
         }
       ]
     }
   }
   
   @description('The host name of the CDN endpoint.')
   output endpointHostName string = endpoint.properties.hostName
   

   This file deploys two resources: a CDN profile and a CDN endpoint.

3. Save the changes to the file.

Add the modules to the main Bicep template

1. Open the main.bicep file.

2. Below the appServicePlanSkuName parameter, add the following parameter:

   @description('Indicates whether a CDN should be deployed.')
   param deployCdn bool = true
   

3. Below the app module definition, define the cdn module:

   module cdn 'modules/cdn.bicep' = if (deployCdn) {
     name: 'toy-launch-cdn'
     params: {
       httpsOnly: true
       originHostName: app.outputs.appServiceAppHostName
     }
   }
   

   Notice that the module has a condition so that it's deployed only when the deployCdn parameter's value is set to true. Also, notice that the module's originHostName parameter is set to the value of the appServiceAppHostName output from the app module.

4. Update the host name output so that it selects the correct host name. When a CDN is deployed, you want the host name to be that of the CDN endpoint.

   output websiteHostName string = deployCdn ? cdn.outputs.endpointHostName : app.outputs.appServiceAppHostName
   

5. Save the changes to the file.

Verify your Bicep file

After you've completed all of the preceding changes, your main.bicep file should look like this example:

@description('The Azure region into which the resources should be deployed.')
param location string = 'westus3'

@description('The name of the App Service app.')
param appServiceAppName string = 'toy-${uniqueString(resourceGroup().id)}'

@description('The name of the App Service plan SKU.')
param appServicePlanSkuName string = 'F1'

@description('Indicates whether a CDN should be deployed.')
param deployCdn bool = true

var appServicePlanName = 'toy-product-launch-plan'

module app 'modules/app.bicep' = {
  name: 'toy-launch-app'
  params: {
    appServiceAppName: appServiceAppName
    appServicePlanName: appServicePlanName
    appServicePlanSkuName: appServicePlanSkuName
    location: location
  }
}

module cdn 'modules/cdn.bicep' = if (deployCdn) {
  name: 'toy-launch-cdn'
  params: {
    httpsOnly: true
    originHostName: app.outputs.appServiceAppHostName
  }
}

@description('The host name to use to access the website.')
output websiteHostName string = deployCdn ? cdn.outputs.endpointHostName : app.outputs.appServiceAppHostName

If it doesn't, either copy the example or adjust your template to match the example.

Deploy the Bicep template to Azure

az bicep install && az bicep upgrade

az deployment group create --name main --template-file main.bicep

New-AzResourceGroupDeployment -Name main -TemplateFile main.bicep

Review the deployment history

1. Sign in to the Azure portal and make sure you're using the appropriate subscription:

   1. Select your avatar in the upper-right corner of the page.
   2. Select Switch directory. In the list, choose the appropriate directory.

2. On the left-side panel, select Resource groups.

3. Select myResourceGroupName.

4. On the left menu, select Deployments under Settings.

   

   Three deployments are listed.

5. Select the main deployment and expand Deployment details.

   Notice that both of the modules are listed, and that their types are displayed as Microsoft.Resources/deployments. The modules are listed twice because their outputs are also referenced within the template.

   

6. Select the toy-launch-cdn and toy-launch-app deployments and review the resources deployed in each. Notice that they correspond to the resources defined in the respective module.

Test the website

1. Select the toy-launch-app deployment.

2. Select Outputs.

   

3. Select the copy button for the appServiceAppHostName output.

4. On a new browser tab, try to go to the address that you copied in the previous step. The address should begin with https://.

   

   The App Service welcome page appears, showing that you've successfully deployed the app.

5. Go to the main deployment and select Outputs.

6. Copy the value of the websiteHostName output. Notice that this host name is different, because it's an Azure Content Delivery Network host name.

7. On a new browser tab, try to go to the host name that you copied in the previous step. Add https:// to the start of the address.

   CDN endpoints take a few minutes to become active. If you get a Page not found error, wait a few minutes and try pasting the link again. Also, ensure that you added https:// to the start of the URL so that you're using HTTPS.

   When the CDN endpoint is active, you'll get the same App Service welcome page. This time, it has been served through the Azure Content Delivery Network service, which helps improve the website's performance.